i assume field1 & field2 are labels objects and you use vfp9
then can use bindevent to solve your problem.run the code and have tests on3 buttons
label1 is autosize=.t.
i use the event "Move" with bindevent.

Publi yform
yform=Newobject("asup")
yform.Show
Read Events
Retu
*
Define Class asup As Form
    Top = 112
    Left = 104
    Height = 250
    Width = 707
    Caption = "Form1"
    Name = "Form1"

    Add Object label1 As Label With ;
        AutoSize = .T., ;
        Caption = "azerty", ;
        Height = 17, ;
        Left = 48, ;
        Top = 24, ;
        Width = 33, ;
        Name = "Label1"

    Add Object label2 As Label With ;
        AutoSize = .F., ;
        FontSize = 12, ;
        Caption = "bzerty", ;
        Height = 21, ;
        Left = 101, ;
        Top = 24, ;
        Width = 43, ;
        ForeColor = Rgb(255,0,0), ;
        Name = "Label2"

    Add Object command1 As CommandButton With ;
        Top = 120, ;
        Left = 84, ;
        Height = 27, ;
        Width = 84, ;
        Caption = "Test1", ;
        Name = "Command1"

    Add Object command2 As CommandButton With ;
        Top = 154, ;
        Left = 85, ;
        Height = 27, ;
        Width = 84, ;
        Caption = "Test2", ;
        Name = "Command2"

    Add Object command3 As CommandButton With ;
        Top = 189, ;
        Left = 85, ;
        Height = 27, ;
        Width = 84, ;
        Caption = "Test3", ;
        Name = "Command3"

    Procedure my
        Lparameters nLeft, nTop, nWidth, nHeight
        Thisform.label2.Left = Thisform.label1.Left + Thisform.label1.Width + 20
    Endproc

    Procedure Init
        Thisform.label2.Left = Thisform.label1.Left + Thisform.label1.Width + 20
        Bindevent(Thisform.label1,"move",Thisform,"my")
    Endproc


    Procedure command1.Click
        Thisform.label1.Caption="ZRAREAEY  ezzezezez zezezzzez"
        Thisform.label1.Move(Thisform.label1.Left)
    Endproc


    Procedure command2.Click
        Thisform.label1.Caption="ZRAREAEY "

        Thisform.label1.Move(Thisform.label1.Left)
    Endproc

    Procedure command3.Click
        Thisform.label1.Caption="ZRAREAEY  ezzezezez zezezzzez ZRAREAEY  ezzezezez zezezzzez"
        Thisform.label1.Move(Thisform.label1.Left)
    Endproc

    Procedure Destroy
        Clea Events
    Endproc


Enddefine
*
*-- EndDefine: asup