Thanks for the tips. I decided to go with the EditBox.

>the dblclick on form grid memo field works as well even in an exe if "screen=on" in config.fpw
>this works for form.showWindow=0,1,2
>the window dblclicked is a child _screen.its visible if _screen.visible=.t.
>
>
>if "screen=OFF" in config.fpw (and mandatory showWindow=2):cannot edit the memo field.by dblClick.you can add
>a check button to switch between screen on/off and edit the memo field if _screen.visible=.t.
>better way make an editbox on the form with controlsource to the cursor memo field and you can see
> visually your memo edited at each grid row clicked.thats is available in all cases.
>add;try this code.can compile an exe (add a config.fpw)
>

>
>Publi yform
>yform=Newobject("asup")
>yform.Show
>Read Events
>Retu
>*
>Define Class asup As Form
>    Top = 86
>    Left = 238
>    Height = 352
>    Width = 282
>    ShowWindow = 2
>    Caption = "Form1"
>    Name = "Form1"
>
>    Add Object grid1 As Grid With ;
>        FontBold = .T., ;
>        FontSize = 10, ;
>        Anchor = 15, ;
>        DeleteMark = .F., ;
>        GridLines = 0, ;
>        Height = 173, ;
>        Left = 4, ;
>        RowHeight = 19, ;
>        Top = 7, ;
>        Width = 260, ;
>        Name = "Grid1"
>
>    Add Object edit1 As EditBox With ;
>        Anchor = 15, ;
>        Height = 161, ;
>        Left = 3, ;
>        Top = 187, ;
>        Width = 265, ;
>        ControlSource = "ycurs.myfield", ;
>        Name = "Edit1"
>
>    Procedure Load
>        _Screen.Visible=.F.
>        Close Data All
>        Create Cursor ycurs (myfield m)
>        TEXT to m.myvar noshow
>		Lorem ipsum dolor sit amet, consectetur adipiscing elit. Proin vel risus eget lorem feugiat
>		fermentum nec a turpis. Phasellus purus sem, mollis ac posuere eget, ornare vel orci. Sed ac rutrum
>		nulla. Aenean ultrices eget lectus eu efficitur. In hac habitasse platea dictumst. Nulla in iaculis nisi.
>		Nullam et pulvinar tellus. Donec arcu dui, efficitur a odio non, porta congue dolor. Aenean viverra
>		auctor sagittis. Integer lobortis dignissim auctor. Proin et volutpat massa.
>        ENDTEXT
>
>        For i=1 To 4
>            Insert Into ycurs Values (Trans(i)+Chr(13)+m.myvar)
>        Endfor
>        *brow
>    Endproc
>
>    Procedure Destroy
>        _Screen.Visible=.T.
>        Clea Events
>    Endproc
>
>    Procedure grid1.Init
>        With This
>            .RecordSource="ycurs"
>            Locate
>        Endwith
>    Endproc
>
>    Procedure grid1.AfterRowColChange
>        Lparameters nColIndex
>        Thisform.edit1.Refresh
>    Endproc
>
>Enddefine
>*
>*-- EndDefine: asup
>