Chang,

If you have multiple TWAIN devices you need to call the ShowSelectScanner() method to allow the user to choose the real device they want. When the imaging app starts up the user may have to select File, Scan New to actually cause the image to be acquired from the device. Here is some code cut directly from the click method of my Scan button, you should be able to follow through it.

with this.parent.oleScanner
   if ( at( '.', this.parent.mcFileName ) = 0 )
      with this.parent
         .mcFileName = .mcFileName + ".tif"
         .cntGetFile.Value = .mcFileName
         .Refresh()
      endwith
   endif

   .Image = this.parent.mcFileName

   local i, liScan

   this.parent.SetStatus( "Select scanner" )
   i = .ShowSelectScanner()
   this.parent.SetStatus( "Opening scanner" )
   i = .OpenScanner()
   this.parent.SetStatus( "Starting the scan" )
   liScan = .StartScan()
   this.parent.SetStatus( "Closing scanner" )
   i = .CloseScanner()
   if ( liScan > 0 )
      this.parent.SetStatus( "Problem with scanner" )
   else
      this.parent.SetStatus( "Done scanning" )

      * update the displays

      with this.parent.oleEdit
         .Image = this.parent.mcFileName
         .Display()
      endwith

      with this.parent.oleThumb
         .Image = this.parent.mcFileName
         .DisplayThumbs()
         .ThumbSelected[this.parent.oleEdit.Page] = .t.
      endwith
      this.parent.ButtonEnable()
   endif

endwith

> Thanks, i have found the control you mention.
> But i faced some problem that is i can't found an image capture property in the Kodak Image Scan Control. When i use the startscan property, it called the Kodak Imaging application. I only can capture the image use the Kodak Imaging.
> Actually, i want to do it in my form by any event(click etc).
> Do you have any sample of it or can you show me how to do it ?
>Thanks for your help.