Cool. Not for this project but I have another project in Beta right now that your editbox would be very useful in.

Thanx.


>Hi Fred.
>
>Just in case you need an edit boc that will expand and let the user see more info (for really long memos), this code in the dlbclick() method of the editbox will give you some addition functionality.
>
>

>LOCAL lnRow,lnColumn
>WITH This
>  IF !.lMaximized
>    .lMaximized = .T.
>    .ZOrder(0)
>    .nOldLeft   = .Left
>    .nOldTop    = .Top
>    .nOldWidth  = .Width
>    .nOldHeight = .Height
>    IF UPPER(ALLTRIM(.Parent.baseclass)) == 'COLUMN'
>       .nOldRowHeight = .Parent.Parent.RowHeight
>       lnRow = .Parent.Parent.ActiveRow
>       lnColumn = .Parent.Parent.ActiveColumn
>       .Parent.Parent.RowHeight = .Parent.Parent.Height
>    ENDIF
>    IF UPPER(ALLTRIM(.Parent.baseclass)) == 'COLUMN' OR ;
>       UPPER(ALLTRIM(.Parent.baseclass)) == 'PAGE'
>       .Top    = .Parent.Parent.Top
>       .Left   = .Parent.Parent.Left
>       .Width  = .Parent.Parent.Width
>       .Height = .Parent.Parent.Height
>    ELSE
>       .Top    = .Parent.Top
>       .Left   = .Parent.Left
>       .Width  = .Parent.Width
>       .Height = .Parent.Height
>    ENDIF
>    IF UPPER(ALLTRIM(.Parent.baseclass)) == 'COLUMN'
>       .Parent.Parent.ActivateCell(lnRow, lnColumn)
>       	DO WHILE .Parent.Parent.RelativeRow <> 1
>       	   .Parent.Parent.DoScroll(1)		&&scoll down
>       	ENDDO
>    ENDIF
>  ELSE
>    .lMaximized = .F.
>    .Left   = .nOldLeft
>    .Top    = .nOldTop
>    .Width  = .nOldWidth
>    .Height = .nOldHeight
>    IF UPPER(ALLTRIM(.Parent.baseclass)) == 'COLUMN'
>       .Parent.Parent.RowHeight = .nOldRowHeight
>    ENDIF
>  ENDIF
>ENDWITH
>

>
>Marcia