>I'm trying to 'hack' the header to convert a Fox 26 file to be a VFP file so I can silently add it to a DBC.
>
>I am writing 30h to the first character of the header file but it moans that the file was created with a pre-release version of VFP - probably a Beta of version 3.
>
>What am I missing?
>

Not only is the value of the byte different, the size of the header is different in later releases of VFP, and other content as well. You'd be much better off doing something like:

PROCEDURE MakeMeAVFPFile
LPARAMETER cFileNameWithoutExtension
LOCAL cTempName, nFH
cTempName = SYS(2015)
USE (cFileNameWithoutExtension) EXCLUSIVE
COPY TO (cTempName) WITH PRODUCTION  && Make an equivalent file in VFP format
USE
FLUSH
nFH = FOPEN(cFileNameWithoutExtension+'.DBF')
DO WHILE nFH = -1  && make sure that we've written the file to disk before proceeding
   nFH = FOPEN(cFileNameWithoutExtension+'.DBF')
ENDDO
=FCLOSE(nFH)
ERASE (cFileNameWithoutExtension + '.DBF')
RENAME (cTempName+'.DBF') TO (cFileNameWithoutExtension + '.DBF')
IF FILE(cFileNameWithoutExtension+'.CDX')
   ERASE (cFileNameWithoutExtension + '.CDX')
   RENAME (cTempName+'.CDX') TO (cFileNameWithoutExtension + '.CDX')
ENDIF
IF FILE(cFileNameWithoutExtension+'.FPT')
   ERASE (cFileNameWithoutExtension + '.FPT')
   RENAME (cTempName+'.FPT') TO (cFileNameWithoutExtension + '.FPT')
ELSE
   *  If it's an old dBASE file, it might have the older .DBT file extension on the memo
   IF FILE(cFileNameWithoutExtension+'.DBT')
      ERASE (cFileNameWithoutExtension + '.DBT')
      RENAME (cTempName+'.FPT') TO (cFileNameWithoutExtension + '.FPT')
   ENDIF
ENDIF
RETURN