Hi Jim,

The problem is that you are using a SELECT statement to create a table (hfboarderror) that you have already indicated is part of the DBC. This is a "no no". You should do one of two things:

1) Get that table out of the DBC if you are going to be recreating it all the time. That's what the SELECT is doing; it's not filling up an existing table.
2) Get that table out of the DBC and create a view with the SELECT statement. Then, requery the view instead of doing the select.

>
>I'm new to dbc's and just created one and added my free tables.
>
>Now I'm running a program that's run fine in the past but now I'm getting an error message:
>
>"File f:\foxdat\hfboarderror.dbf already exits as part of a database"
>
>Options are to "Cancel -Suspend -Ignore"
>
>Here is the method where it hangs, I believe on the first line:
>
>***check board method
>select hfboarderror
>zap
>cwaitmessage = "Please be patient, checking board information in the master table..."
>wait cwaitmessage window at 14,25 nowait
>select location, yr_bred, name, comp_no, acct_no, date_arr, date_left, transient ;
>from master ;
>where (date_arr = {} and date_left <> {} and acct_no <> "26853") ;
>or ;
>((date_arr < ThisForm.Hstxtbegin.value and date_arr <> {}) and date_left = {} and transient and acct_no <> "26853") ;
>or ;
>(date_arr >= ThisForm.Hstxtbegin.value and date_left = {} and transient and acct_no <> "26853") ;
>or ;
>(date_arr >= ThisForm.Hstxtbegin.value and date_left <= ThisForm.Hstxtend.value and transient and acct_no <> "26853") ;
>or ;
>(date_arr < ThisForm.Hstxtbegin.value and date_left <= ThisForm.Hstxtend.value and transient and acct_no = "26853") ;
>or ;
>(date_arr = {} and location <> " " and acct_no <> "26853") ;
>or ;
>(date_arr <> {} and date_left = {} and location = " " and acct_no <> "26853") ;
>or ;
>(date_arr > thisform.hstxtend.value) ;
>into table hfboarderror nofilter
>wait clear
>select hfboarderror
>inde on comp_no tag comp_no
>if reccount() > 0
>cmessagetitle = "Board Errors"
>cmessagetext = "Errors have been found in the master.dbf table." + chr(13);
>+ "You must print a report and correct errors before continuing." + chr(13) ;
>+ "Click 'Yes' to continue, 'No' to exit."
>ndialogtype = 4 + 48 + 0
>nanswer = messagebox(cmessagetext, ndialogtype, cmessagetitle)
>do case
>case nanswer = 6 && yes
>repo form hsrpboarderror to print prompt noconsole
>thisform.release
>case nanswer = 7 && no
>thisform.release
>endcase
>else
>ThisForm.Hscmdcreate.visible = .t.
>ThisForm.Hscmdcreate.setfocus()
>ThisForm.Hschkboard.value = 1
>ThisForm.Hschkboard.visible = .t.
>ThisForm.Hschkboard.caption = "Completed"
>ThisForm.Hschkboard.enabled = .f.
>ThisForm.Hscmdcheck.enabled = .f.
>thisform.refresh
>endif
>
>
>Can anyone see why having a dbc would cause this program to stop running?
>
>Thanks,
>
>Jim Harvey
>jharvey@netrax.net