>With the v2.0 and v2.2 this driver give me GPF in my report's
>What to do... what to do..... say to my client´s change printer or there are other solution ???
>I have to install the windows 98 HP Deskjet driver, for stoping the GPF, but the reports have some colores .
>
>Thank you ALL,
>
>João.

Joao,

I have the same printer with the French drivers installed, and no problem to date. Should the problem arise from the information left in the TAG, TAG2 fields of the report at design time? I have a small utility that cleans the reports before they go to the customer's.

*  Program...........: CLEANREPS.PRG
*  Author............: José Constant                      
*  Project...........: PROSAL                             
*  Created...........: 19/01/99  11:09:21
*  Copyright.........: (c) Terre-Engineering S.A., 1999
*  Compiler..........: Visual FoxPro 05.00.00.0415 for Windows 
*) Description.......: Cleans reports header
*                    : Published by Josh Weiss on the Universal Thread
*  Calling Samples...: 
*  Parameter List....: 
*  Major change list.: 

LOCAL lcGetDIR

CD (GETDIR("" , 'Où se trouvent les rapports'))

SET MEMOWIDTH TO 1024
DIMENSION aFileType[2]
aFileType[1]='*.FRX'
aFileType[2]='*.LBX'


FOR EACH cFileType IN aFileType
  nNumReps=ADIR(aReps,m.cFileType)
  WAIT WINDOW NOWAIT ALLTRIM( STR( nNumReps)) + " " + m.cFileType
  INKEY( 1)
  FOR i=1 TO nNumReps
    USE (aReps[i,1])
    LOCATE FOR ObjType=1
    IF FOUND()
      REPLACE TAG WITH ''
      REPLACE Tag2 WITH ''
      m.cExpr=Expr
      FOR j=1 TO MEMLINES(m.cExpr)
        m.cLine=MLINE(m.cExpr,j)
        IF m.cLine='ORIENTATION'
          EXIT
        ENDIF
      NEXT
      REPLACE Expr WITH IIF(m.cLine='ORIENTATION',m.cLine,'')
    ENDIF
  NEXT
  CLOSE DATA ALL
ENDFOR

CD ..

José