>Hi Cetin,
>
>I'm running VFP 6.0 on an NT 4.0 workstation with 128mg.
>
>It appears that I have happened upon an anomaly that others may have encountered also.
>
>In a SQL Select statement that has the parameter 'Into Table TableName', if TableName is not in the path I get a "String too long to fit" message on the entire Select statement of course.
>
>In the app I'm currently have a problem with I setup the following:
>
>lcTempDir = "C:\CVS\"
>
>other code...later after creating a Word Object:
>
>lcDocument=lcTempDir+"BetExp01.doc"
>.Documents.open(lcDocument)
>
>If BetExp01.doc is not in the path I get a "String too long to fit" message at the .Documents.open(lcDocument) statement.
Paige,
I think the error here is related with SQL statement used in mailmerge (I guess this is part of an mailmerge). In ODBC connect string there are 2 SQLstring parameters. Each could hold up to 255 chars. Probably you use only the first one and if path gets long 255 is exceeded. When it's exceeded second SQLstring should be used. You could work around it :
lcSQL1 = iif(len(lcSQL) > 255, left(lcSQL,255), lcSQL)
lcSQL2 = iif(len(lcSQL) > 255, substr(lcSQL,256), "")
Better yet I would suggest not to use mailmerge with ODBC at all :) Here is a sample of whatI do :
Wait window nowait "Creating Word Document.Please wait..."
#include "wdconst.h"
#Define NL chr(13)
#Define TABULATE chr(9)
Select * from (_samples+"\data\employee") where Title like "%Manager%" into table Tempreport
lnFields=_CopyDataToClipBoard("Tempreport","first_name,last_name,title,hire_date,notes")
nlLocaleId=sys(3004)
=sys(3006,1033)
Public oWordDocument
oWordDocument=createobject("word.application")
With oWordDocument
.documents.add
With .ActiveDocument
.PageSetup.Orientation = wdOrientLandscape
.Range.Paste
.Range.ConvertToTable(wdSeparateByTabs,,lnFields,,wdTableFormatContemporary,,,,,,,,,.f.)
.Range.Find.Execute("~",,,,,,,,,"^p",wdReplaceAll)
Endwith
=_SampleMerge(.f.)
.ActiveDocument.MailMerge.Destination = wdSendToNewDocument
.ActiveDocument.MailMerge.Execute
.ActiveDocument.Range.Find.Execute("^b",,,,,,,,,"^p^p[End of Merge]^p",wdReplaceAll)
.visible = .t.
.Activate
Endwith
Wait clear
=sys(3006,val(nlLocaleId))
Function _CopyDataToClipBoard
Lparameters tcTableName, tcFieldList
lcOldAlias = Alias()
Select &tcFieldList ;
from (tcTableName) ;
nofilter into cursor crsTemp
If reccount("crsTemp")=0
Use in "crsTemp"
Return
Endif
Select crsTemp
lnFields = fcount()
lcTempFileName = "X"+sys(2015)+".tmp"
handle = fcreate(lcTempFileName)
For ix = 1 to lnFields
=fwrite(handle, field(ix))
If ix < lnFields
=fwrite(handle, TABULATE)
Endif
Endfor
=fwrite(handle, NL)
Scan
For ix = 1 to lnFields
=fwrite(handle, TypeConvert(ix) )
If ix < lnFields
=fwrite(handle, TABULATE)
Endif
Endfor
=fwrite(handle, NL)
Endscan
lnSize=fseek(handle,0,2)
=fseek(handle,0,0)
_Cliptext = fread(handle, lnSize)
=fclose(handle)
Erase (lcTempFileName)
Use in "crsTemp"
If !empty(lcOldAlias)
Select (lcOldAlias)
Endif
Return lnFields
Function TypeConvert
Lparameters tnField
lcType = type(field(ix))
luValue = eval(field(ix))
Do case
Case lcType = "D"
lcValue = dtoc(luValue)
Case lcType = "T"
lcValue = ttoc(luValue)
Case lcType = "N"
lcValue = padl(luValue,20," ")
Case lcType = "L"
lcValue = iif(luValue,"Yes","No")
Case lcType $ "MC"
lcValue = chrtran(strtran(luValue, chr(13)+chr(10), "~"),chr(9),space(4))
Otherwise
lcValue = ""
Endcase
Return alltrim(lcValue)
Function _SampleMerge
Lparameters tlToPrinter
With oWordDocument
lcTempDataDoc = sys(5)+curdir()+"T"+sys(2015)+".doc"
With .ActiveDocument
.SaveAs(lcTempDataDoc)
.Close(wdSaveChanges)
Endwith
.documents.add
With .ActiveDocument.MailMerge
.OpenDataSource(lcTempDataDoc)
.EditMainDocument
Endwith
.Application.Selection.TypeText("Dear,"+chr(13))
.ActiveDocument.MailMerge.Fields.Add(.Application.Selection.Range, "LAST_NAME")
.Application.Selection.TypeText(", ")
.ActiveDocument.MailMerge.Fields.Add(.Application.Selection.Range, "FIRST_NAME")
.Application.Selection.TypeText(chr(13)+"Here is your notes data :"+chr(13)+chr(13))
.ActiveDocument.MailMerge.Fields.Add(.Application.Selection.Range, "NOTES")
.Application.Selection.TypeText(chr(13)+chr(13)+"As to our records you were hired on ")
.ActiveDocument.MailMerge.Fields.Add(.Application.Selection.Range, "HIRE_DATE")
.Application.Selection.TypeText(" with title [")
.ActiveDocument.MailMerge.Fields.Add(.Application.Selection.Range, "TITLE")
.Application.Selection.TypeText("]"+chr(13)+"Thanks"+chr(13)+"Yours Sincerely."+chr(13)+"Blah blah...")
EndwithCetin
>
>I've resolved these problems but now get the message "String too long to fit" at the .application.run("Replace") command in the routine below used to replace text in a Word template.
>
>NewText = MDY(DATE()) && Thanks to Bret
>DO WordRepl WITH "<
>", NewText
>
>WordRepl Routine follows:
>
>Lparameters OldText, NewText
>*
>* Replace All OldText with NewText
>*
>
>WITH oWORDDOC
>
> .Selection.Find.ClearFormatting
> .Selection.Find.Replacement.ClearFormatting
>
> .Selection.Find.Text = OldText
> .Selection.Find.Replacement.Text = NewText
> .Selection.Find.Wrap = 1
> .Selection.Find.Format = .f.
> .Selection.Find.MatchCase = .f.
> .Selection.Find.MatchWholeWord = .f.
> * Word.Selection.Find.MatchWildcards = False
> * Word.Selection.Find.MatchSoundsLike = False
> * Word.Selection.Find.MatchAllWordForms = False
>
> .application.run("replace")
>
>ENDWITH
>
>I don't know how much memory the RUN command requires. I could be running out of memory on the users workstation although she has 128mg on her Win98 workstation but is running from a NT 4.0 server.
>
>Sys(1016) returns 726624 on my workstation just prior to executing the Run command. I havn't checked her machine.
>
>There may be a more efficient method to accomplish the Word Replace. I use this to "REPLACE" name, address, and other data in the template also. If you know a better way I would appreciate you sharing it with me. TIA.
>
>Regards,
>
>Paige
