Kim:

I once coded this for an Tax Audit app. Some of the properties are not in the VFP base class but they aree not that important.

* -- atlasTextBox - RightClick event
* -- -------------------------------
* -- Displays a utility menu.

LOCAL lcChoice && The user selection.
LOCAL lcCut && prompt.
LOCAL lcCopy && prompt.
LOCAL lcPaste && prompt.
LOCAL lcSelectAll && prompt.
LOCAL lcSpellCheck && prompt.
LOCAL lcWhatsThis && prompt.
LOCAL llSkipCut && True if the prompt is disabled.
LOCAL llSkipCopy && True if the prompt is disabled.
LOCAL llSkipPaste && True if the prompt is disabled.
LOCAL llSkipSelectAll && True if the prompt is disabled.
LOCAL llSkipSpellCheck && True if the prompt is disabled.
LOCAL llSkipWhatsThis && True if the prompt is disabled.

lcCut = POPMENU_CUT
llSkipCut = (NOT THIS.Enabled) OR THIS.ReadOnly OR(THIS.SelLength = 0)

lcCopy = POPMENU_COPY
llSkipCopy = (THIS.SelLength = 0)

lcPaste = POPMENU_PASTE
llSkipPaste = (NOT THIS.Enabled) OR THIS.ReadOnly OR EMPTY(_CLIPTEXT)

lcSelectAll = POPMENU_SELECTALL
llSkipSelectAll = .F.

lcSpellCheck = POPMENU_SPELLCHECK
llSkipSpellCheck = (NOT THIS.Enabled) OR THIS.ReadOnly OR (NOT THIS.SpellCheck)

lcWhatsThis = POPMENU_WHATSTHIS
llSkipWhatsThis = .F.

DEFINE POPUP popMenu ;
FROM MROW(), MCOL() ;
FONT 'Arial', 9 ;
STYLE 'N' ;
SHORTCUT

DEFINE BAR 1 OF popMenu PROMPT m.lcCut SKIP FOR m.llSkipCut
DEFINE BAR 2 OF popMenu PROMPT m.lcCopy SKIP FOR m.llSkipCopy
DEFINE BAR 3 OF popMenu PROMPT m.lcPaste SKIP FOR m.llSkipPaste
DEFINE BAR 4 OF popMenu PROMPT '\-'
DEFINE BAR 5 OF popMenu PROMPT m.lcSelectAll SKIP FOR m.llSkipSelectAll
DEFINE BAR 6 OF popMenu PROMPT '\-'
DEFINE BAR 7 OF popMenu PROMPT m.lcSpellCheck SKIP FOR m.llSkipSpellCheck
DEFINE BAR 8 OF popMenu PROMPT '\-'
DEFINE BAR 9 OF popMenu PROMPT m.lcWhatsThis SKIP FOR m.llSkipWhatsThis

ON SELECTION POPUP popMenu lcChoice = PROMPT()
ACTIVATE POPUP popMenu

IF TYPE("m.lcChoice") == "C"
DO CASE
CASE m.lcChoice == STRTRAN(m.lcCut, '\<', '')
=SYS(1500, '_MED_CUT', '_MEDIT')
CASE m.lcChoice == STRTRAN(m.lcCopy, '\<', '')
=SYS(1500, '_MED_COPY', '_MEDIT')
CASE m.lcChoice == STRTRAN(m.lcPaste, '\<', '')
=SYS(1500, '_MED_PASTE', '_MEDIT')
CASE m.lcChoice == STRTRAN(m.lcSelectAll, '\<', '')
=SYS(1500, '_MED_SLCTA', '_MEDIT')
CASE m.lcChoice == STRTRAN(m.lcSpellCheck, '\<', '')
THISFORM.FoxSpell_Call()
CASE m.lcChoice == STRTRAN(m.lcWhatsThis, '\<', '')
THIS.ShowWhatsThis(THIS.WhatsThisHelpId)
ENDCASE
ENDIF