You'll need to track the contol you're over and change the Value on the fly, but it works.

PUBLIC oForm1
oForm1 = CREAT([oForm])
oForm1.oTip1.TOP = oForm1.oButton1.TOP - 22
oForm1.oTip1.LEFT = oForm1.oButton1.LEFT + oForm1.oButton1.WIDTH/2 - oForm1.oTip1.WIDTH/2
oForm1.SHOW

DEFINE CLASS oForm AS FORM
	AUTOCENTER = .T.
	ADD OBJECT oButton1 AS oButton
	ADD OBJECT oTip1 AS oTip
	PROC MOUSEMOVE
	LPARAMETERS nButton, nShift, nXCoord, nYCoord
	THIS.oTip1.VISIBLE = .F.
ENDPROC
ENDDEFINE

DEFINE CLASS oButton AS COMMANDBUTTON
	LEFT = 120
	TOP = 100
	WIDTH = 150
	HEIGHT = 25
	CAPTION = [Place the mouse here]
	PROC MOUSEMOVE
	LPARAMETERS nButton, nShift, nXCoord, nYCoord
	THISFORM.oTip1.VISIBLE = .T.
ENDPROC
ENDDEFINE

DEFINE CLASS oTip AS TEXTBOX
	VISIBLE = .F.
	ENABLED = .F.
	SPECIALEFFECT = 1
	FONTNAME = [MS Sans Sarif]
	HEIGHT = 19
	DISABLEDBACKCOLOR = RGB(255,255,128)
	DISABLEDFORECOLOR = RGB(0,0,0)
	VALUE = [Tip Text]
ENDDEFINE

Dave


>What do you suggest?
>
>>You could roll your own toolip.
>
>>>It's positioned relative to the mouse not the control. Tell them to hold the mouse higher *g*
>
>>>>Is it possible to display a tooltip at the top of a control (in this case a button) instead of the bottom. Buttons on at the bottom of a form just above the Windows taskbar have their tooltip obscured by the freakin' taskbar.