Judith,
I tried to email sampling here but my mailserver :( Anyway constructing these 2 forms wouldn't take much time.

*Form - dialog1 - 4 objects, list1, command1, command2, command3
* DE has only customer
* List1 init
*PROCEDURE list1.Init
With this
  .RowSourceType = 3
  .RowSource = "select company,contact,cust_id from customer into cursor crsMyList"
  .Columncount = 3
  .Boundcolumn = 3
  .Columnwidths = '200,140,45'
  .MultiSelect = .T.
  .Width = 410
Endwith

*	command1
*Caption = "Show Selected Recs in Grid Forms"
*PROCEDURE command1.Click
With ThisForm.List1
  nInstance = 0
  For ix = 1 to .ListCount
    If .selected(ix)
      nInstance = nInstance + 1
      Do form dialog2 with .list(ix,3), nInstance
    Endif
  Endfor
Endwith

*Command2
*Caption = "Exit"
*PROCEDURE command2.Click
Thisform.release

*Command3
*Caption = "Exit closing all windows"
*PROCEDURE command3.Click
For ix = _screen.Formcount to 1 step -1
  _Screen.Forms(ix).Release
Endfor

*Form - dialog2
*DataSession = 2 && Private datasession - DE has customer and orders with no relation
* Grid with properties - recordsource orders
*ChildOrder = "cust_id"
*LinkMaster = "customer"
*RecordSource = "orders"
*RecordSourceType = 1
*RelationalExpr = "cust_id"
*PROCEDURE Init
Lparameters tcCust_id, tnInstance
Select customer
Locate for cust_id = tcCust_id
With this
  .Caption = 'Orders for '+customer.company
  Store tnInstance * 10 to .Left, .Top
Endwith

Cetin