Hi Jill,

Here is 5:07 pm right now :)
In my case I just put this macros in VFP home directory, I think, and called it default.fky. Therefore I don't have the problem, you described.

You may also do OKL in your VFPStartUP program, if the macros idea would not work for you. Sometimes there is no way to achieve desired functionality by macro.

This is my VFPStart program: (in home() directory)

********************************************************************
*  Description.......: Startup program for Visual FoxPro
*  Calling Samples...: 
*  Parameter List....: 
*  Created by........:  
*  Modified by.......: Nadya Nosonovsky 10/10/2000 09:35:26 AM
********************************************************************
local lcPath
lcPath=set('path')
set path to (home()+iif(!empty(lcPath),', '+lcPath,''))
if not "FOXTOOLS.FLL" $ upper(set("library"))
     set library to home()+'Foxtools.fll' additive
endif

on key label F7 do home()+'InsertDesc.prg' && Insert description (title)
on key label F8 do home()+'ls.app' with .t. && John Koziol utility to list table structure
on key label f3 keyboard 'Nadya Nosonovsky '+ttoc(datetime()) plain && Insert modidate
on key label f9 _cliptext=nnHTMLcode(_cliptext) && WEB nice formatting (NN version)
on key label f10 _cliptext=mmHTMLCode(_cliptext) && WEB nice formatting (Mike Helland version)

* Nadya Nosonovsky 03/29/2000 01:47:15 PM
on key label F12 activate window debug && Debug should be available 
********* EView - Erik Moore EView - very powerful tool for manipulating with views
DEFINE BAR 8 OF _MTOOLS PROMPT "\-"
DEFINE BAR 9 OF _MTOOLS PROMPT "EView..."

ON SELECTION BAR 9 OF _MTOOLS do c:\UtFiles\EView\eview.app && EView app

*********** George Tasker FoxTools Help ****************
DEFINE BAR 8 OF _MSM_SYSTM PROMPT "\-"
DEFINE BAR 9 OF _MSM_SYSTM PROMPT "FoxTools Help"

ON SELECTION BAR 9 OF _MSM_SYSTM do home()+'ToolHelp.prg'

*_screen.caption=version()

*set default to (getdir('d:\redp\appl\','Select directory to start'))

_screen.icon='d:\redp\appl\commonwg\bmps\wlogo.ico' && Change screen icon

_screen.caption=space(20)+'My wonderful VFP SP4  '+ ;
     space(50)+' '+cmonth(date())+ ;
     ' '+alltrim(str(day(date())))+', ' ;
     +alltrim(str(year(date())))
cOldScreenCaption=_screen.caption

***** Nancy Folsom code, but I don't understand its advantage, so commented it out **********
*!*     LOCAL lnBar
*!*     lnBar = CNTBAR('_MTOOLS') + 1
*!*     DEFINE BAR lnBar OF _MTOOLS PROMPT [ClassBrowser...]
*!*     ON SELECTION BAR lnBar OF _MTOOLS do (_browser) with getfile('VCX')
*!*     lnBar = lnBar + 1

********************************************************************
*  Description.......: Inserts description into open edditing window
*  Calling Samples...: ON KEY LABEL F7 do InsertDesc
*  Parameter List....: 
*  Created by........: Ken Weber 12/28/99
*  Modified by.......: Nadya Nosonovsky 01/03/2000 10:18:11 AM
********************************************************************
local cClipText

cClipText = filetostr(home()+'Description.txt')
_ClipText=cClipText
keyboard '{ctrl+v}' plain

HTH


>Good morning Nadya,
>
>>To extend your idea a little bit: create a macro for cleaning. For instance, I have bunch of useful macros in my VFP Environment. In my case clearing environment is on F4. Also don't forget to reset menu to default.
>
>Great idea - thanks...should have done this long ago...I've just taken your idea and created my macro, and saved it in a myMacros.fky...
>
>I put a line in a VFPStart program, that is run from Config.sys, that restores the macros:
>
>RESTORE MACROS FROM c:\progra~1\devstudio\VFP\MyMacros.fky
>
>but that doesn't seem to do it...if I execute that line in the Command window, it works...any ideas for me? (I may be missing somthing obvious - it's EARLY, and someone from NY woke me up at 3:00 AM and I haven't been back to sleep....)
>
>Thanks for your help on this....J