>Hi All,
>
>Could someone please tell me the name of the MS treeview control's ocx
>
>TIA

Mike,

While you already have your answer, there is a way to do this programmatically. Using the registry class that comes with VFP 6.0

#INCLUDE REGISTRY.H
SET CLASSLIB TO REGISTRY ADDITIVE
oReg = CREATEOBJECT('REGISTRY')
RELEASE CLASSLIB REGISTRY
* lcServer is server Object or ActiveX control
* MSTreeview is MSComCtlLib.TreeCtrl.2
IF oReg.OpenKey(lcserver + '\CLSID') = ERROR_SUCCESS
  lcCLSID = ""
  lnerr = oReg.GetKeyValue("", @lcCLSID)
  IF lnerr = ERROR_SUCCESS
    oReg.CloseKey()
    lckey = "Software\Classes\CLSID\" + lcCLSID + "\InProcServer32"
    IF oReg.OpenKey(lckey, HKEY_LOCAL_MACHINE) = ERROR_SUCCESS
      lcdll = ""
      lnerr = oReg.GetKeyValue("", @lcdll)
      IF lnerr = ERROR_SUCCESS
        ? lcdll
      ELSE
        ? lnerr
      ENDIF
      oReg.CloseKey()
    ELSE
      ? "Can't open CLSID key"
    ENDIF
  ELSE
    ? lnerr
  ENDIF
  oReg.CloseKey()
ELSE
  ? "Can't open key"
ENDIF