>I have an app written in VFP5, and i have just discovered that the source code has been altered and not made live, I'm not sure when this was amended.
>
>All I've got to go on is that when I compile the source, the EXE is larger than the live version.
>
>Anyone got any suggestions, should I make MY changes and then distribute the EXE - or is there anything else I can do?
>
>Thanks
>Kev

Here are a couple of things you can check:

Are there deleted records in any table-type files (VCX, SCX, FRX, MNX)? (Particularly VCX and SCX files) Pack all of these before compiling. e.g.

** PackProj.prg
LParameters tcProject
Local ji, laFiles(1), lcFile, lcProject, lnTally
Assert Vartype(tcProject)="C"
lcProject = ForceExt(tcProject,"pjx")
If !File(lcProject)
  MessageBox(lcProject + " not found.")
  Return
EndIf
  
Select PadR(Strtran(name, Chr(0)), 75) ;
  From (lcProject) ;
  Where type $ "VKRM" ;
  Into Array laFiles
lnTally =  _Tally
Use

If lnTally > 0
  For ji = 1 To lnTally
    lcFile = Alltrim(laFiles[ji])
    Wait Window lcFile NoWait
    Use (lcFile) Exclusive
    Pack
  EndFor 
  Use
  Wait Clear
EndIf

Was Debug Info checked (in the Project Info dialog) in development and not live when compiled?