>Next year, the in-house application (written in VFP 5.0) that I and a small staff of others help write and support is going to get a make-over. The compiled application is getting very large (almost 2 meg) and we're thinking about breaking it up into separate executables, with the main one called the other "sub-programs" when needed.
>
>Is there anything we need to keep in mind while evaluating the possibility of doing this? Any suggestions on how to make it as easy as possible? Any words of wisdom? Any and all help would be GREATLY appreciated!
>
>Thanks in advance for your help....

2M is big????
Yeesh, ours is pushing 20M.

One good thing to do is to pack all your VCX and SCX files before doing the build. Here's one way to do it that's pretty quick:

*--     PackProj.prg
*     by Trey Walpole
LParameters tcProject
Local laFiles(1), lcCurDir, lcFile, lcProject, lnFileCnt
Store "" To lcCurDir, lcFile, lcProject
Store 0 To lnFileCnt

*--     make sure a project was passed in...
If Vartype(tcProject)#"C"
     MessageBox("Project name required.")
     Return
EndIf
lcProject = ForceExt(tcProject,"pjx")

*... and that it exists
If !File(lcProject)
     MessageBox("Project " + lcProject + " not found.")
     Return
EndIf

*--     switch to project's directory
*     to take advantage of the relative paths
lcCurDir = FullPath(CurDir())
CD (JustPath(FullPath(lcProject)))

*--     get all files from project of these types
*     V - VCX
*     K - SCX
*     R - FRX
*     M - MNX
*     d - DBC
Select 0
Select name ;
     From (lcProject) ;
     Where type $ "VKRMd" ;
     And File(Chrtran(Alltrim(name),Chr(0),"")) ;
     Into Array laFiles
lnFileCnt = _Tally
Use && close up the PJX table

*--     loop through and pack the files
For ji = 1 To lnFileCnt
     lcFile = Chrtran(laFiles[ji],Chr(0),"")
     Wait Window "Packing: " + Chr(13) + lcFile Nowait
     Use (lcFile) Exclusive
     Pack
     Use
EndFor

*--     clean up
Wait Clear
CD (lcCurDir)