Hi Gerry,
Just in case anyone cares, try running this. Then open many tables with many fields and run again. Your results may vary. In general you should see "m." helps more as the ambiguity increases. The difference isn't worth mentioning either way. Ironic.

LOCAL ScenerioToRun, StartSeconds, TestScenerio, ;
	RunNumber, Description

SET TALK OFF

Description = ""
=RAND(-1)
CREATE CURSOR Results (Scenerio C(10), ElaspedTime N(7,4), ;
	Description C(48))
FOR m.TestScenerio = 1 TO 30
	ScenerioToRun = "Scenerio" + STR(INT(RAND()*3) + 1,1)
	
	StartSeconds = SECONDS()
	FOR RunNumber = 1 TO 1000
		DO (m.ScenerioToRun) WITH m.Description
	ENDFOR
	ElaspedTime = SECONDS() - m.StartSeconds	
	WAIT WINDOW STR(m.ElaspedTime,7,4) + ;
		" time elasped for " + m.ScenerioToRun NOWAIT
	Scenerio = ScenerioToRun
	INSERT INTO Results FROM MEMVAR
ENDFOR
WAIT CLEAR
SELECT Scenerio, AVG(ElaspedTime), COUNT(Scenerio), Description ;
	FROM Results ;
	GROUP BY Scenerio 
USE IN Results
USE IN Query
RETURN

************************
PROCEDURE Scenerio1	
	LPARAMETER Description 	&& Passed by reference.
	Description = 'With "m." everywhere.'
	
	LOCAL m.Var, m.Var1, m.Var2, m.Var3, m.Var4, ;
		m.Var5, m.Var6, m.Var7, m.Var8
	m.Var = 2
	m.Var2 = "asdf"
	m.Var3 = {}
	m.Var4 = 432432.123456
	m.Var5 = m.Var
	m.Var6 = m.Var2
	m.Var7 = m.Var3
	m.Var8 = m.Var4
	m.Var9 = SUBSTR(m.Var2, 1, m.Var)
	RETURN
ENDPROC

************************
PROCEDURE Scenerio2	
	LPARAMETER Description 	&& Passed by reference.
	Description = 'With NO "m." anywhere.'
	
	LOCAL Var, Var1, Var2, Var3, Var4, ;
		Var5, Var6, Var7, Var8
	Var = 2
	Var2 = "asdf"
	Var3 = {}
	Var4 = 432432.123456
	Var5 = Var
	Var6 = Var2
	Var7 = Var3
	Var8 = Var4
	Var9 = SUBSTR(Var2, 1, Var)
	RETURN
ENDPROC	

************************
PROCEDURE Scenerio3	
	LPARAMETER Description 	&& Passed by reference.
	Description = '"m." only where required to eliminate ambiguity.'
	LOCAL Var, Var1, Var2, Var3, Var4, ;
		Var5, Var6, Var7, Var8
	Var = 2
	Var2 = "asdf"
	Var3 = {}
	Var4 = 432432.123456
	Var5 = m.Var
	Var6 = m.Var2
	Var7 = m.Var3
	Var8 = m.Var4
	Var9 = SUBSTR(m.Var2, 1, m.Var)
	RETURN 
ENDPROC