>Using VB6.
>
>My app has a MDI form that is opened with WindowState = 2. Another form called menu is opened inside the MDI form.
>
>How can I make the menu form open up centered in the MDI form? I tried placing Me.StartUpPosition = 1 in the menu form's LOAD(). However, when I do this, I get a VB error when running the form. The message starts with:
> Function or interface marked as restricted
>
>How can I get any form to startup centered in a MDI form?
>
>Thanks,
>
>Jerryt

Here are a few things I use with MDI forms. HTH.

Public Sub Center(frm As Form, Optional frmMDI As Variant)
Dim ret
    'Syntax: Center Form1, [MDIForm1]
    ret = IsMissing(frmMDI)

    If ret = False Then
        frm.Top = (frmMDI.ScaleHeight - frm.Height) / 2
        frm.Left = (frmMDI.ScaleWidth - frm.Width) / 2
    Else
        frm.Top = (Screen.Height - frm.Height) / 2
        frm.Left = (Screen.Width - frm.Width) / 2
    End If
End Sub

Public Sub CenterChild(Parent As Form, Child As Form)
    'Syntax: CenterChild MDIForm1, Form1
    Dim iTop As Integer
    Dim iLeft As Integer
    If Parent.WindowState <> 0 Then Exit Sub
    iTop = ((Parent.Height - Child.Height) \ 2)
    iLeft = ((Parent.Width - Child.Width) \ 2)
    Child.Move iLeft, iTop ' (This is more efficient than setting Top and Left properties)
End Sub
 
Public Sub UnloadAllChildren()
    Dim vForm As Variant
    For Each vForm In Forms
        If Not TypeOf vForm Is MDIForm Then
            If vForm.MDIChild Then
                Unload vForm
            End If
        End If
    Next  'vFrom
End Sub