>I am attempting to use the SuperMover Foundation Class for the first time (For that matter, Any Foundation Class for the first time). Could anyone talk me through it like I'm a nine-year old. That way if I'm confused, I can have my kids (or staff) help out.
>
>So Far, I have place the SuperMover on a form. That's it. How do I populate the left ListBox, etc. Thanks in advance...
>
>
>Jamie

Jaime,
ROFL.
OK let's go :
-In a test directory create a test form
-You already know this step, drop a Supermover on your form
-In form init (not a must place - it could be later even a commandbutton click code) create a ONE dimensional array (any array would do).
-Call Supermover's InitChoices method with this array. ie:

*form.init
select first_name-(' '+last_name) from employee into array arrSelections
THISFORM._SuperMover1.InitChoices(@arrSelections)

That's all.
BTW if you initially want to start with some selections you can use :
THISFORM._SuperMover1.InitSelections(@arrSelections)
in the same manner. ie:

select first_name-(' '+last_name) ;
   where first_name # 'A' ;
   from employee into array arrChoices && Not beginning with 'A' are choices
select first_name-(' '+last_name) ;
   where first_name = 'A' ;
   from employee into array arrSelections && Beginning with 'A' are selected
with THISFORM._SuperMover1
  .sizetocontainer() 
  .SortLeft = .t. && Sort choices
  .InitChoices(@arrChoices)
  .InitSelections(@arrSelections)
endwith

To get selections back you use supermover's getselections method. ie:

* a commandbutton.click
dimension arrWhatIsSelected[1]
thisform._SuperMover1.GetSelections(@arrWhatIsSelected)
if type('arrWhatIsSelected')='L'
    wait window 'Nothing selected' timeout 2
else
    activate screen
    clear
    for ix=1 to alen(arrWhatIsSelected)
	? arrWhatIsSelected[ix]
    endfor
endif

Cetin