>>Alexander,
>>
>>Thanks, that did the trick. Now all I have to do is get my JPG detail right so when it stretchs it doesn't lose quality.
>>
>>Thanks Again
>>Elgin
>>
>
>Elgin,
>
>That is good.
>BTW, will be your screen resized? If so your background image will not be centered and you need to move it somethere in your code, maybe using timer for that.


You don't need a timer. You can add method code for _SCREEN like this:

*
* ScreenMethods.PRG
*
* Fred Taylor - ElZorro 4/10/2001  www.elzorro.org
*
* Use the following to modify _SCREEN methods:
*
* For VFP6 & 7:
*
*     _SCREEN.NewObject("oSH","ScreenHook","screenmethods.prg")
*
* For VFP3 & 5:
*
*     SET PROCEDURE TO screenmethods ADDITIVE
*     _SCREEN.AddObject("oSH","ScreenHook")
*
* Any of the main VFP screen methods can be hooked into in this manner.
* A similar technique can also be used to hook methods of grid
* headers, etc., at run-time.
*
DEFINE CLASS ScreenHook AS CUSTOM
oScr = _SCREEN
PROCEDURE oScr.Resize()
  *
  * Code to handle the main VFP screen being resized
  *
  WAIT WINDOW NOWAIT TRANSFORM(this.Width)+" "+TRANSFORM(this.Height)
ENDPROC
PROCEDURE oScr.RightClick
  *
  * Code to do a "shortcut" menu on main VFP screen RightClick
  *
  DO testmenu.mpr
ENDPROC
ENDDEFINE