>Dear all,
>
>Is that true that this version of VFP doesnot support the GIF animation?
>Is there any alternative to aid the case? and,
>Will there be supporting planned in the coming releasing VP 7.0?
>
>Regards,
>
>Ransome

Ransome,
True and false :) True VFP doesn't have direct support for animated gif (shows w/o animation). OTOH there is activex web browser control which you could place on form and set URL to file. ie :

oForm = createobject('form1')
oForm.Show
Read events

Define CLASS form1 AS form
  Top = 0
  Left = 0
  Height = 467
  Width = 577
  DoCreate = .T.
  Caption = "Form1"
  Name = "Form1"

  Add OBJECT command1 AS commandbutton WITH ;
    Top = 360, ;
    Left = 468, ;
    Height = 27, ;
    Width = 84, ;
    Caption = "Change", ;
    Name = "Command1"

  Add OBJECT container1 AS container WITH ;
    Top = 0, ;
    Left = 0, ;
    Width = 420, ;
    Height = 457, ;
    BorderWidth = 0, ;
    Name = "Container1"


  Procedure Init
  With ThisForm.container1
    .NewObject('_webbrowser','_webbrowser4',home()+'gallery\_webview.vcx')
    With ._WebBrowser
      .Height = 450
      .Width = 450
      .visible = .t.
      .Navigate('file://C:/WINDOWS/SYSTEM/OOBE/HTML/MOUSE/IMAGES/moving.gif')
    Endwith
    .setfocus()
  Endwith
  Thisform.command1.Setfocus()
Endproc

  Procedure command1.Click
  Thisform.container1._WebBrowser.Navigate('file://C:/WINDOWS/SYSTEM/OOBE/HTML/MOUSE/IMAGES/dragging.gif')
Endproc
  Procedure QueryUnload
  Clear events
Endproc
Enddefine

Cetin