>has anyone succesfully used dynazip to span disks?
>
>everything we've tried with dynazip works great except i get an ole error "out of present range" when i set MultiVolumeControl to MV_USEMULTI.
>it tried hard coding both the decimal and hex values also and got the same error.

Gray,

I have a simple backup/restore form I use with my applications that use dynazip. The form has a combo-box for the user to select Drive A, Drive B, or Hard Drive; a check box if the user wants to format the diskette first; and a command button to start the backup. The following is my code for the backup command button:

*****************************************************************************
#DEFINE ZIP_ADD 4
#DEFINE MV_USEMULTI -32768
#DEFINE MV_FORMAT 1
#DEFINE MV_LOWDENSE 2
#DEFINE MV_WIPE 256
#DEFINE MV_SUBDIR 512
#DEFINE MV_SYSHIDE 1024
#DEFINE MV_CDFIRST 4096

* Setup zip property defaults
ThisForm.initZipdefault() && I set all my defaults for zip operations here

* Setup zip properties to those on the form
drivedest = ThisForm.PageFrame.Page1.cboDriveDest.Value && Drive destination combo box

IF drivedest = 'Drive A' OR drivedest = 'Drive B'
DO CASE
CASE drivedest = 'Drive A'
ThisForm.dZip.ZIPFile = 'a:\tss.zip'
CASE drivedest = 'Drive B'
ThisForm.dZip.ZIPFile = 'b:\tss.zip'
ENDCASE
IF ThisForm.PageFrame.Page1.chkFormat.Value && Format check box
mvsettings = MV_USEMULTI + MV_FORMAT
ELSE
mvsettings = MV_USEMULTI
ENDIF
ThisForm.dZip.MultiVolumeControl = mvsettings
ENDIF

oldAutoYield = _VFP.AutoYield
_VFP.AutoYield = .F.

* Do the ZIP
ThisForm.dZip.ActionDZ = ZIP_ADD

_VFP.AutoYield = oldAutoYield

IF ThisForm.dZip.ErrorCode = 0
= MESSAGEBOX('Backup Successful!',48,'Backup Status')
ENDIF

****************************************************************************
Notice the application AutoYield property before and after the launching of dynazip. This one caused me grief until talking to dynazips tech support. Like I said, dynazip has been working perfectly. Dynazip allows you to change the error titles and messages to match your application. I hope this helps you out!

James