>Can someone tell me the meaning of the Clear item in the Window menu?
>I
>always have this disable in my application.
>
>I was also wondering about Cascade. Has someone did a class to
>simulate a
>Cascade operation as we can do in most of other applications?
Here's some code from my generic procedure file:
procedure SysCascadeWindows
*****
* Procedure : SysCascadeWindows
* Programmer : Paul Russell
* Purpose : Cascade any Open windows that have Borders
* Date : 12-August-97
*
* Description:
*
* Restrictions:
*
* Parameters:
*
* Returns:
*
* Sample Call:
*
* Calls:
*
* Variables:
*
* Databases:
*
* Change Log :
* PAR - Created
*
******
private all like lp*
*****
* Determine how many characters to move the Windows
* This is the Standard Windows Border + the Size of the Close box.
*****
m.lpOffset = sysmetric(3)+sysmetric(5)
m.lpFormNumber = 0
m.lpFormLevel = 10
*****
* Work with each valid form in turn
* 1) The form must exist
* 2) It must be a Form (not a Toolbar)
* 3) The form must be Visible and Active
* 4) The form must have a Border
*****
for m.lpCount = _screen.FormCount to 1 step -1
if type("_screen.forms(m.lpCount)") = "O" and ;
(not IsNull(_screen.forms(m.lpCount))) and ;
_screen.forms(m.lpCount).BaseClass = "Form" and ;
_screen.forms(m.lpCount).Visible and ;
_screen.forms(m.lpCount).Enabled and ;
_screen.forms(m.lpCount).BorderStyle # 0
*****
* Move the Form
*****
_screen.forms(m.lpCount).Top = m.lpFormNumber * m.lpOffset
_screen.forms(m.lpCount).Left = m.lpFormNumber * m.lpOffset
*****
* Update the number of Forms that have been moved
*****
if m.lpFormNumber = m.lpFormLevel
m.lpFormNumber = 0
else
m.lpFormNumber = m.lpFormNumber + 1
endif
endif
endfor
return
procedure SysCloseAllForms
*****
* Procedure : SysCloseAllForms
* Programmer : Paul Russell
* Purpose : Close all of the open windows
* Date : 12-August-97
*
* Description:
*
* Restrictions:
*
* Parameters:
*
* Returns:
*
* Sample Call:
*
* Calls:
*
* Variables:
*
* Databases:
*
* Change Log :
* PAR - Created
*
******
private all like lp*
*****
* Work with each valid form in turn
* 1) The form must exist
* 2) It must be a Form (not a Toolbar)
* 3) The form must be Visible and Active
* 4) The form must have a Border
*****
for m.lpCount = _screen.FormCount to 1 step -1
if type("_screen.forms(m.lpCount)") = "O" and ;
(not IsNull(_screen.forms(m.lpCount))) and ;
_screen.forms(m.lpCount).BaseClass = "Form" and ;
_screen.forms(m.lpCount).Visible and ;
_screen.forms(m.lpCount).Enabled and ;
_screen.forms(m.lpCount).BorderStyle # 0
*****
* Close the Form
*****
_screen.forms(m.lpCount).Release
endif
endfor
return
