>I have a infrared remote control and I'm trying to get data from COM1 with code below but nothing happen.
>Any suggestion?
>Thank's in advance,
>NPedro
>
>
>
>Do WHILE !OK
> IF THISFORM.c.InBufferCount > 0
> cChar = THISFORM.c.Input
> OK = .T.
> Endif
>Enddo
>
>wait wind "Result: " + cChar

Hi Nuno,
I also tried to read data from MSComm for GPS data and was getting nothing. Finally I got this working code :

* load mscomm
oComm = CREATEOBJ('MSCOMMLib.MSComm')
* Open and Initialize COM port #1 for use
With oComm
  .CommPort = 1
  .Settings = "4800,N,8,1"
  .InputLen = 1
  .PortOpen = .T.

  lcDATA=''
  lnStart = datetime()
  llDataReady = .F.
  Do while datetime()-lnStart < 5
    .InputLen = 1
    lcDATA = lcDATA+.input
    lnGGA = at('$GPGGA',lcDATA)
    lnGSA = at('$GPGSA',lcDATA)
    If lnGGA > 0 and lnGSA > lnGGA && Read enough
      llDataReady = .T.
      Exit
    Endif
  Enddo
  * Close the port
  .PortOpen = .F.
Endwith
Release oComm
If llDataReady
  Thisform.WriteGPSData(lcDATA, datetime())
Else
  Wait window timeout 2 'GPS timedout!'
Endif

Cetin