>Hallo everyone
>I have 2 questions that I would be very happy to get answers to:
>Is there any command/function in VFP I can use to automatically fill a primary/candidate key field with a new unique number when I save a new record? Or must I make my own function?
>If a network user is locking a record or table and not release it, is there a way to figure out who it can be. So I can call him, and tell him to release the lock.
>I hope you understand what I mean.
>Thanks in advance
>/Kjell

My version. Save this function in database stored procedures. See comments in function.

**********************************************************************
FUNCTION SERIALNUMBER(tnSequence)
	* Get serial number. Used mainly to generate primary keys.
	* The easiest way to achieve this is to call this function from a fields default value.
	* This function accesses table SerialNumber. Fields: Sequence C(30), NextNum I.
	tnSequence = lower(tnSequence)
	local lnSelect
	lnSelect = select()
	if used("serialnumber")
		select serialnumber
	else
		select 0
		use serialnumber
	endif
	set order to "sequence"
	seek padr(tnSequence, len(sequence))
	if not found()
		append blank
		replace sequence with tnSequence, nextnum with 1
	endif
	local lnReturnValue
	if lock()
		lnReturnValue = nextnum
		replace nextnum with nextnum + 1
	else
		lnReturnValue = -1
	endif
	unlock
	select (lnSelect)
	return lnReturnValue
ENDFUNC