>Is this available?
>
>>... I even wrote a utility PRG to strip these relative paths from these properties.

Here it is. Just make sure you back up the SCX and SCT files before using it.

set talk off
set deleted on
cursorsetprop('buffering', 1, 0)
local lnRetVal, i, j, lcFile, llFound, lcStr, lcPath, laFiles(1,2)
lnRetVal = adir(laFiles, "forms\*.scx")
for i = 1 to lnRetVal
   lcFile = laFiles(i,1)
   use "forms\" + lcFile excl
   locate for "DATABASE" $upper(Properties)
   do while !eof()
      llFound = .f.
      for j = 1 to memlines(properties)
         if alltrim(upper(substr(mline(properties, j), 1, 8))) = "DATABASE"
            llFound = .t.
            exit
         endif
      next
      if llFound
         lcStr = mline(properties, j)
         lcStr = alltrim(substr(lcStr, 11))
         lcPath = justpath(lcStr)
         lcPath = addbs(lcPath)
         replace next 1 properties with strtran(properties, lcPath, "")
      endif
      continue
   enddo
   pack
   use
   compile form "Forms\" + lcFile
next