>Hi:
>
>I´m trying to get the CLSID from a COM object.
>I´ve registered the dll file. I can make the object but when I put "object.CLSID", it appears an OLE error message (Unkown name). What´s the problem?
>Could you help me?

Xabi,
CLSID applies to server object. When your project is active :

oServer = _VFP.ActiveProject.Servers("classnamehere")
? oServer.CLSID

If you mean to read from registry :
? _GetClassCLSID('word.application')
? _GetClassCLSID('myCOMDLL.myClass')

*function _GetClassCLSID
Lparameters tcClassName
#Define HKEY_CLASSES_ROOT   -2147483648
#Define ERROR_SUCCESS		0	&& OK

Declare Integer RegOpenKey IN Win32API ;
  Integer nHKey, String @cSubKey, Integer @nResult

Declare Integer RegCloseKey IN Win32API ;
  Integer nHKey

Declare Integer RegQueryValueEx IN Win32API ;
  Integer nHKey, String lpszValueName, Integer dwReserved,;
  Integer @lpdwType, String @lpbData, Integer @lpcbData

Local lnKey,lpdwReserved,lpdwType,lpbData,lpcbData,nErrCode,CLSID
Store 0 TO lpdwReserved,lpdwType
Store SPACE(256) TO lpbData
Store LEN(m.lpbData) TO m.lpcbData

lnKey = 0
llRetVal = ( RegOpenKey(HKEY_CLASSES_ROOT, tcClassName+'\CLSID', @lnKey) = ERROR_SUCCESS )
If llRetVal
  If RegQueryValueEx(lnKey,'',;
      m.lpdwReserved,@lpdwType,@lpbData,@lpcbData) = ERROR_SUCCESS
    m.CLSID = LEFT(m.lpbData,m.lpcbData-1)
  Else
    m.CLSID = ''
  Endif
  RegCloseKey(lnKey)
Endif
Return m.CLSID

Cetin