>Is the an easy way to size a browse window. I am doing a lot of data manipulation on tables and have about 15 tables open at once. There are relations set so I have 6 or so tables that I am viewing at one time. I need to have other tables visible for various reasons.
>
>I use the tables for other reasons and sometimes they get moved and when I open the mentioned session again I need to rearrange them to get them located the way I like them. I am now using DEFINE WINDOW for them but wonder if there is another method?
>
>I just want the tables to be placed at certain places on the screen and be of a certain dimension. (and don't want to deal with multiple resource files)
>
>Thanks!
Jim,
Using name clause you could manage browse windows as grid objects. ie:

use employee
browse fields last_name, ;
	first_name,;
	empname=Last_Name-(', '+employee.first_name) name "myBrowse" when SetDyn()

function SetDyn
lnRecno = recno()
with myBrowse
  .recordMark = .f.
  .deletemark = .f.
  .GridLines = 0
  .scrollbars = 2
  .AllowRowSizing = .f.
  .AllowHeaderSizing = .f.
  .setall("SelectOnEntry",.f.)
  .Setall("DynamicBackColor","iif(recno()="+str(lnRecno)+","+;
  	str(.Columns(1).Text1.SelectedBackColor)+;
  	",iif(recno()%2=0,rgb(255,255,128),rgb(128,255,255)))","column")
  .Setall("DynamicForeColor","iif(recno()="+str(lnRecno)+","+;
  	str(.Columns(1).Text1.SelectedForeColor)+","+str(.Forecolor)+")","column")
  with .Columns(3)
  	.Header1.Caption = 'Emp.FullName and Title (added later)'
  	.Controlsource = "employee.Last_Name-(', '+employee.first_name)-(' ['+employee.Title-']')"
  	.Fontbold = .T.
  	.Columnorder = 2
	.Width = 300
  endwith
  .Width = 500
  .Height = 300
  .Top = 100
  .Left = 100
endwith

Cetin