Try this:
* Yuri Rubinov July 2000
* Remove printer specific setting in report form
*---------------------------------------------------

PARAMETER pRepoForm
if type("pRepoForM")#"C"
	pRepoForm=getfile("frx")
endif

do case
case upper(pRepoForm)#"ALL"
	pRepoForm=lower(pRepoform)
	if not ".frx"$pRepoform
		pRepoform=pRepoform+".frx"
	endif
	if not file(pRepoform)
		=messagebox("Report Form "+pRepoform +" not found?!")
		return
	endif
	do iClean
otherwise
	*WHAT ABOUT PAGE Orientation?
	if adir(aa,"*.frx")<=0
		=messagebox("No *.frx Report Forms found?!")
		return
	endif
	for ia =1 to alen(aa,1)
		pRepoForm=aa[ia,1]
		do iClean
	endfor

endcase

*----------------------------------
Procedure iClean

close table all
use (pRepoform)
wait wind time 0.5 "Report form "+dbf()
=afield(afld)
* the very first record only
if ascan(afld,"TAG")#0 and ascan(afld,"TAG2")#0 and ascan(afld,"EXPR")#0
	go top
	*keep orientation
	lcorient=""
	if "orientation"$lower(expr)
		lcorient=substr(expr,at("orientation=",lower(expr)),15)
	endif
	replace tag with "", tag2 with "", expr with lcorient
else
	=messagebox("File "+pRepoform+". Not VFP6 format?!")
endif

use
*-----------------

>Hi everybody,
>
>I saw people mentioned the program written to remove printer specific info from the report files in the directory (Select report files from some directory). I don't want to re-invent the wheel. Could you please share this program, if you have it?
>
>Thanks a lot in advance.