I had a problem where a particular file wouldn't compile. So I wrote a little program to scan the PJX and compile each file. Anything that failed for any reason just printed the name of the file.

Here's the code. I call it mycompile.prg. It could be enhanced (what can't?) to let you specify the project, but its easy enough to change the code as it stands.

local lcOnError
lcOnError = ON("ERROR")
local lcName
lcName = ""
on error do comperr with lcName
local lcAlias
lcAlias = ALIAS()
SELECT 0
USE MI.PJX AGAIN alias myproj
LOCAL lcTalk
lcTalk = SET("talk")
SET TALK OFF
SCAN
  lcName = myproj.name
  DO CASE
  CASE INLIST(TYPE,"xi")
    LOOP
  CASE TYPE = "M" && menu
    LOOP
  CASE TYPE = "P" && PROGRAM
    COMPILE (m.lcName)
  CASE TYPE = "R" && REPORT
    COMPILE (m.lcName)
  CASE TYPE = "K" && SCREEN
    COMPILE FORM (m.lcName)
  CASE TYPE = "V" && CLASSLIB (VCX)
    COMPILE classlib (m.lcName)
  ENDCASE
  WAIT WINDOW lcName NOWAIT
ENDSCAN
use in myproj
if !empty(lcAlias)
  select (lcAlias)
endif
ON ERROR &lcOnError
SET TALK &lcTalk
return 

procedure comperr
lparameters tcName
?tcName
return

>I tried compile classlib on the classes that I have make any recent changes to and have had no problems. I did not check them all, but I do not know why the others would have a problem I also tried to compile my forms and did not have a problem there either. Build EXE with or without the compile files checked still gives me an error "line is too long."