Hi,

>Does any one know if vpf 8.0 has auto hide feature for the windows,same as vs.net ?

Here's a sample program I wrote some time ago to simulate this behavior. It only deals with the Command window, but you should be able to expand on this, if you want.

Public goCommand as Toolbar
goCommand = CreateObject("FlyOut")
goCommand.Show()

Define Class FlyOut as Toolbar

 tmr = NULL

 Add Object chk as Checkbox with ;
  Style = 1, ;
  Caption = "Normal", ;
  Height = 20, ;
  Width = 65, ;
  Value = .F.
 
 Procedure Init
  This.tmr = CreateObject("FlyOutTimer")
  This.tmr.cName = This.Name
 EndProc 
 
 Procedure chk.MouseMove
  Lparameters t1,t2,t3,t4
  If Thisform.Docked and This.Value and not Thisform.tmr.Enabled
   If not WDockable("Command")
    WDockable("Command",.T.)
   EndIf 
   Dock Window Command Position Thisform.DockPosition
   Thisform.tmr.Interval = 500
   Thisform.tmr.Enabled = .T.
  EndIf 
 EndProc
 
 Procedure chk.Click
  If This.Value
   This.Caption = "FlyOut"
  Else
   This.Caption = "Normal"
   Thisform.tmr.Interval = 0
   Thisform.tmr.Enabled = .F.
   Show Window Command
  EndIf 
 
EndDefine 

Define Class FlyOutTimer as Timer
 cName = ""
 Enabled = .F.
 Procedure Timer
  If    Upper(Mwindow()) == "COMMAND" ;
     or Upper(Mwindow()) == Upper(This.cName) ;
     or Mcol("") == -1 and Mrow("") == -1
  Else
   Hide Window Command
   This.Interval = 0
   This.Enabled = .F.
  EndIf 
 EndProc 
EndDefine 

Christof