Joel,

I use this code to pack everything that's in the project file:

LPARAMETERS lcProj

IF VARTYPE(lcProj) # "C"
	WAIT WINDOW "Project name must be specified." NOWAIT
	RETURN
ENDIF

lcProj = FORCEEXT(lcProj, "PJX")

IF !FILE(lcProj)
	WAIT WINDOW "Can't find project specified." NOWAIT
	RETURN
ENDIF

CLOSE ALL

USE (lcProj) ALIAS source EXCLUSIVE

SCAN FOR source.type$"KRVMD"
	lcFile = LEFT(source.name, LEN(source.name) - 1)
	IF FILE(lcFile)
		= ADIR(laFiles, lcFile)
		IF "R"$laFiles[1, 5] = .F.
			WAIT WINDOW "Packing:" + CHR(13) + lcFile NOWAIT
			SELECT 0
			USE (lcFile) ALIAS tmp EXCLUSIVE
			PACK
			USE
			SELECT source
		ENDIF
	ENDIF
ENDSCAN

WAIT WINDOW "Packing project" NOWAIT

SELECT source
PACK

WAIT WINDOW "Packing finished!" NOWAIT

USE

>I have an old Fox 6 application that I give to my client as an EXE.
>
>It has been being about 1 meg for several years. Suddenly it is 2.6 meg and I can not see what I have added to increase that size.
>
>How do I find my problem???
>
>Is there a way to know what makes up the EXE?
>
>THanks
>Joel Hokanson
>Houston