Hi Rob,

I may be missing the boat here, but something simple in VFP:

oform = createobject("form1")
oform.Show()
READ EVENTS
RELEASE oform

DEFINE CLASS form1 AS form
  HEIGHT = 81
  WIDTH = 249
  DOCREATE = .T.
  AUTOCENTER = .T.
  onmess = "Working"
  offmess = "Gone fishing"
  NAME = "Form1"
  CAPTION = "Making Busy Work"

  ADD OBJECT timer1 AS TIMER WITH ;
    TOP = 20, ;
    LEFT = 20, ;
    HEIGHT = 23, ;
    WIDTH = 23, ;
    INTERVAL = 1000, ;
    NAME = "Timer1"

  ADD OBJECT text1 AS TEXTBOX WITH ;
    HEIGHT = 23, ;
    LEFT = 38, ;
    TOP = 25, ;
    WIDTH = 180, ;
    NAME = "Text1"

  PROCEDURE timer1.TIMER
    WITH THISFORM
      IF .text1.VALUE = .offmess
        .text1.VALUE = .onmess
        KEYBOARD "{HOME}"
      ELSE
        .text1.VALUE = .offmess
        KEYBOARD "{END}"
      ENDIF
    ENDWITH
  ENDPROC
  
  PROCEDURE DESTROY
    CLEAR EVENTS
  ENDPROC

ENDDEFINE

may provide enough activity for you. Set the interval to what ever you might desire.

>"I'd like to comment on one thing. You mentioned that you would be
>installing the Focalpoint Print Manager (FPM) software on a machine in
>the back office. That's OK, but that machine will require some keyboard
>activity in order to maintain the VPN connection. In other words, in
>order for FPM to continue to receive messages, the VPN must remain on
>and connected. Due to keyboard inactivity, the VPN will drop after a
>period of time. If that machine will be used by someone in the office,
>that's great. If not, the better thought might be to have FPM loaded on
>a machine that gets some activity."
>