>Hola a todos!
>
>¿Alguien por ahí tendrá un tip para hacer o emular un campo autoincremental a nivel de tabla en una BD versión 7?
>
>De antemano gracias...
>
>L.I. Humberto Ramírez
>Operadora de la Cuenca del Pacífico, S.A. de C.V.
>Manzanillo, Col.
>México

Puedes usar mi función SerialNumber(). Asígnalo al valor default de un campo. Primero tienes que crear la tabla. Si quieres usarla para códigos que ve el usuario, la tabla de secuencias tiene que ser parte de tu base de datos, para que pueda participar en transacciones.

**********************************************************************
FUNCTION SerialNumber(tcSequence)
	* Get serial number. Used mainly to generate primary keys.
	* The easiest way to achieve this is to call this function from a fields default value.
	* Example: default value for primary key "Client" of table "Client" = SerialNumber("Client")
	* This function accesses table SerialNumber. Fields: Sequence C(30), NextNum I.
	tcSequence = lower(tcSequence)
	local lnSelect
	lnSelect = select()
	if used("serialnumber")
		select serialnumber
	else
		select 0
		use serialnumber
	endif
	set order to "sequence"
	seek padr(tcSequence, len(sequence))
	if not found()
		append blank
		replace sequence with tcSequence, nextnum with 1
	endif
	local lnReturnValue
	if lock()
		lnReturnValue = nextnum
		replace nextnum with nextnum + 1
	else
		lnReturnValue = -1
	endif
	unlock
	select (lnSelect)
	return lnReturnValue
ENDFUNC