Kenneth,

I use the this code to clean up my project:

LPARAMETERS lcProj

IF VARTYPE(lcProj) # "C"
	WAIT WINDOW "Project name must be specified." NOWAIT
	RETURN
ENDIF

lcProj = FORCEEXT(lcProj, "PJX")

IF !FILE(lcProj)
	WAIT WINDOW "Can't find project specified." NOWAIT
	RETURN
ENDIF

CLOSE ALL

USE (lcProj) ALIAS source EXCLUSIVE

SCAN FOR source.type$"KRVMD"
	lcFile = LEFT(source.name, LEN(source.name) - 1)
	IF FILE(lcFile)
		= ADIR(laFiles, lcFile)
		IF "R"$laFiles[1, 5] = .F.
			WAIT WINDOW "Packing:" + CHR(13) + lcFile NOWAIT
			SELECT 0
			USE (lcFile) ALIAS tmp EXCLUSIVE
			IF JUSTEXT(UPPER(lcFile)) = "FRX"
				SELECT Tmp
				GO TOP
				REPLACE Tmp.Tag		WITH SPACE(0)
				REPLACE Tmp.Tag2	WITH SPACE(0)
				IF "ORIENTATION=1"$Expr
					REPLACE Tmp.Expr WITH "ORIENTATION=1"
				ELSE
					REPLACE Tmp.Expr WITH SPACE(0)
				ENDIF
			ENDIF
			PACK
			USE
			SELECT source
		ENDIF
	ENDIF
ENDSCAN

WAIT WINDOW "Packing project" NOWAIT

SELECT source
PACK

WAIT WINDOW "Packing finished!" NOWAIT

USE

>Hi,
>
>I did a couple of modifications on my project, and the exe-file went from 1 MB to 7 MB...
>
>The only things I did was adding fields to 3 tables and making a new form.
>
>Can anyone give me some help on how to reduce the size of the EXE-file?
>
>I'm using VFP 6.0
>
>
>Regards,
>
>Kenneth Ingebrigtsen