>Cathy, Zapping (or removing) the FOXUSER file seems to help with the reports toolbar issue.

Denis,

I know you're talking about the distributed app/exe, not your development environment, but when I first ran into this problem in the VFP5 development environment I made a program to fix it. (And I'm continually adding to the program as I find other FoxUser issues/clutter I want to deal with.)

The problem: if you do a REPORT PREVIEW with SET RESOURCE ON, it changes your FoxUser record for the MODIFY REPORT position for that report, and messes up your report toolbars for every report.

I wrote a prg called PurgReso, to correct this and other problems I found beginning to clutter up or harm my FoxUser file. Here's a portion of it:

* PurgReso.prg
*
* Clean some junk out of the current resource file, if any.
local lcSetExac, lcSetReso, lnSele

if empty(set("resource", 1) )
	messagebox("No resource file is specified", ;
		0, "No Resource File")
	return
endif
if !file(set("resource", 1) )
	messagebox("Specified resource file (" ;
		+ set("resource", 1) + ") does not exist.", ;
		0, "No Resource File")
	return
endif

lcSetExac = set("exact")
set exact off
lcSetReso = set("resource")
set resource off
lnSele = select()

select 0
use (set("resource", 1) ) exclusive

* I like to keep only the DEFAULT record
* for each type of MODIFY window.
delete for id = "WIND" ;
	and not (empty(name) or name='.' or name="DEFAULT")

* Check whether a Report Preview has messed up the Report Toolbars
locate for id = "TTOOLBAR" and name = "Print Preview"
if found()
	delete
	delete for id = "REPORTTOOLS"
endif

pack
pack memo
use

select (lnSele)
set resource &lcSetReso
set exact &lcSetExac
* eof: PurgReso.prg