>I created a CA to test if CA makes Data conversion and used SQL-Server's Northwind database orders table.
Snip...
>When I browse the cursor it returns the data, but it doesnt convert the fields:
>ORDERDATE, REQUIREDDATE and SHIPPEDDATE from Time to Date.
>
>Where should I change the datatype in CA ? , I thing it was in CursorSchema...
>What I'm missing in CA ?
>
>Thanks in Advance
>
>Peter

Peter,
I think what you're missing is the first parameter of CursorFill(lUseCursorSchema). Here is a revised version of your code :

oData = Createobject("NWData")
Browse
Tableupdate()

Define Class NWData As CursorAdapter
  DataSourceType="ODBC"
  Alias="Orders"

  CursorSchema = "CUSTOMERID C(5), EMPLOYEEID I, FREIGHT Y, "+;
    "ORDERDATE D, ORDERID I, REQUIREDDATE D, "+;
    "SHIPADDRESS C(60), SHIPCITY C(15), SHIPCOUNTRY C(15), "+;
    "SHIPNAME C(40), SHIPPEDDATE D, SHIPPOSTALCODE C (10), "+;
    "SHIPREGION C(15), SHIPVIA I"
  SelectCmd = "select Orders.CUSTOMERID, Orders.EMPLOYEEID,"+;
    "Orders.FREIGHT,"Orders.ORDERDATE, Orders.ORDERID,"+;
    "Orders.REQUIREDDATE,Orders.SHIPADDRESS, Orders.SHIPCITY,"+;
    "Orders.SHIPCOUNTRY, Orders.SHIPNAME, Orders.SHIPPEDDATE,"+;
    "Orders.SHIPPOSTALCODE, Orders.SHIPREGION, Orders.SHIPVIA "+;
    " from Orders"

  Tables = "Orders"
  KeyFieldList = "CUSTOMERID"
  UpdatableFieldList = "EMPLOYEEID, FREIGHT, ORDERDATE, ORDERID,"+;
    "REQUIREDDATE, SHIPADDRESS, SHIPCITY, "+;
    "SHIPCOUNTRY, SHIPNAME, SHIPPEDDATE, SHIPPOSTALCODE, SHIPREGION, SHIPVIA"
  UpdateNameList = "CUSTOMERID Orders.CUSTOMERID, "+;
    "EMPLOYEEID Orders.EMPLOYEEID, FREIGHT Orders.FREIGHT, "+;
    "ORDERDATE Orders.ORDERDATE, ORDERID Orders.ORDERID, "+;
    "REQUIREDDATE Orders.REQUIREDDATE, SHIPADDRESS Orders.SHIPADDRESS, "+;
    "SHIPCITY Orders.SHIPCITY, SHIPCOUNTRY Orders.SHIPCOUNTRY, "+;
    "SHIPNAME Orders.SHIPNAME, SHIPPEDDATE Orders.SHIPPEDDATE, "+;
    "SHIPPOSTALCODE Orders.SHIPPOSTALCODE, "+;
    "SHIPREGION Orders.SHIPREGION, SHIPVIA Orders.SHIPVIA"

  Procedure Init
    This.AddProperty('Connection',;
      SQLSTRINGCONNECT(;
      "Driver=SQL Server;Server=servername;"+;
      "Trusted_connection=Yes;"+;
      "DATABASE=Northwind"))
    This.Datasource = This.Connection
    This.CursorFill(.T.)
  Endproc
Enddefine

Cetin