>Hi all
>
>Is there anybody using InnoSetup for a VFP6SP5 application. If so could you share the basic script with me. I am currently using Visual Stuodio Installer but would like more control.
>
>Any other alternative other then Inno and IS.

Here's a skeleton script showing a sample EXE and a readme file, along with the VFP6 SP5 runtime files. Of course, you'll need to adapt this script to your own situation. HTH.

[Setup]
AppName=My Program
AppVerName=My Program 1.0
AppPublisher=My Company, Inc.
AppPublisherURL=http://www.mycompany.com
AppSupportURL=http://www.mycompany.com
AppUpdatesURL=http://www.mycompany.com
DefaultDirName={pf}\My Program
DefaultGroupName=My Program

[Tasks]
Name: desktopicon; Description: Create a &desktop icon; GroupDescription: Additional icons:
Name: quicklaunchicon; Description: Create a &Quick Launch icon; GroupDescription: Additional icons:; Flags: unchecked

[Files]
Source: C:\MyVFPApps\MyProg\myprog.exe; DestDir: {app}; Flags: ignoreversion
Source: C:\MyVFPApps\MyProg\readme.txt; DestDir: {app}; Flags: ignoreversion

;**********************************************************************
;
;	VFP6 SP5 Runtime Files, et. al. --> {sys} directory
;
; NOTE: Don't use "Flags: ignoreversion" on any shared system files
;
;**********************************************************************
;	VFP6 SP5 runtime files
Source: C:\WINNT\System32\Vfp6r.dll; DestDir: {sys}; Flags: regserver sharedfile uninsneveruninstall restartreplace
Source: C:\WINNT\System32\Vfp6renu.dll; DestDir: {sys}; Flags: sharedfile uninsneveruninstall restartreplace
Source: C:\WINNT\System32\Vfp6run.exe; DestDir: {sys}; Flags: sharedfile uninsneveruninstall restartreplace
Source: C:\WINNT\System32\Vfp6t.dll; DestDir: {sys}; Flags: sharedfile uninsneveruninstall restartreplace
;	Visual C++ support files
Source: C:\WINNT\System32\Mfc40.dll; DestDir: {sys}; Flags: regserver uninsneveruninstall onlyifdoesntexist
Source: C:\WINNT\System32\Msvcrt40.dll; DestDir: {sys}; Flags: uninsneveruninstall onlyifdoesntexist
;	HTML Help for VFP6
Source: C:\WINNT\System32\Foxhhelp.exe; DestDir: {sys}; Flags: sharedfile uninsneveruninstall restartreplace
Source: C:\WINNT\System32\foxhhelpps.dll; DestDir: {sys}; Flags: regserver sharedfile restartreplace uninsneveruninstall

[Icons]
Name: {group}\My Program; Filename: {app}\myprog.exe
Name: {group}\Uninstall My Program; Filename: {uninstallexe}
Name: {userdesktop}\My Program; Filename: {app}\myprog.exe; Tasks: desktopicon
Name: {userappdata}\Microsoft\Internet Explorer\Quick Launch\My Program; Filename: {app}\myprog.exe; Tasks: quicklaunchicon

[Run]
Filename: {sys}\Foxhhelp.exe; Parameters: /RegServer
Filename: {sys}\Vfp6run.exe; Parameters: /RegServer
Filename: {app}\myprog.exe; Description: Launch My Program; Flags: nowait postinstall skipifsilent
Filename: {app}\readme.txt; Description: View the README file; Flags: postinstall shellexec skipifsilent skipifdoesntexist