>Hi everyone:
>
>I have one here that's killing me. We have an VFP/SQL server application that uses remotes views against a SQL server 2000. The problem is that in our location works perfectly (duh...common phrase for us programmers), but at one (only one) of our clients always hangs while querying or updating. After many days trying to figure it out we ran the sql profiler against both databases and we found that in our client's server.... every query or update is preceded by a "SET IMPLICIT_TRANSACTIONS ON". In our location we don't have that.
>
>We are thinking that's something related to ther odbc drivers. Please help ....!!!!!

Probably, SQL server itself is configured globally that way (Server\Properties\Connections tab).
You can programatically check, modify it (sysadmin/serveradmin) using sp_configure globally. ie:

local lnHandle
lnHandle=SQLStringConnect(;
'DRIVER=SQL Server;SERVER=servername;User ID=uid;Password=pwd')

* Check
SQLEXEC(lnHandle, "sp_configure @configname='user options'",'curConfig')
? 'Implicit transactions are '+;
   Iif( Bittest(CurConfig.Config_value,1), 'on', 'off')

* Turn off
SQLEXEC(lnHandle, "sp_configure @configname='user options', "+;
   "@configvalue="+;
   Transform(BitClear(CurConfig.Config_value,1)))

SQLEXEC(lnHandle, "sp_configure @configname='user options'",'newConfig')
? 'Implicit transactions are now '+;
   Iif( Bittest(newConfig.Config_value,1), 'on', 'off')

* Restore
SQLEXEC(lnHandle, "sp_configure @configname='user options', "+;
   "@configvalue="+;
   Transform(CurConfig.Config_value))
SQLEXEC(lnHandle, "sp_configure @configname='user options'",'sqlConfig')
   
? 'Implicit transactions are restored to '+;
   Iif( Bittest(sqlConfig.Config_value,1), 'on', 'off')

SQLDisconnect(lnHandle)

OLEDB and ODBC drivers automatically turn if OFF on connection. So I think you're right suspecting the driver.
Cetin