>I have a text file that contains compy info records that I need to import into FoxPro. Easy enough. Well the problem is, is that this file has the records input a little different. Instead of having a company, address, phone, fax info as different fields; it displays each field as a different record. How it is displayed is:
>ABC Company
>123 West St
>Some City, OH 55555-5555
>Phone: 555-555-5555 Fax: 555-555-5555
>
>There is a blank after each company record. How do I go about importing these files into a dbf but have each company record display in it's correct fields?
>
>Thank you,
>Julie

Julie,
As always there are multiple ways. Assuming it has no more than 65000 lines :

lnLines = alines(arrContent,FileToStr('importme.txt'))
lnLinesPerRecord = 4+1 && 1 blank
lnRows = ceiling(lnLines/lnLinesPerRecord)
dimension arrContent[lnRows,lnLinesPerRecord]
For ix=1 to lnLinesPerRecord
  If Type('arrContent[lnRows,ix]')='L'
    arrContent[lnRows,ix] = ''
  endif
endfor
Select myTable
Append From array arrContent

Another way might be do some xml processing. ie:

lnHandle = Fopen('importme.txt')
Set Textmerge To importme.XML Noshow
Set Textmerge On
\\<?xml version = "1.0" encoding="Windows-1252" standalone="yes"?>
\<VFPData>
Do While !Feof(lnHandle)
	\<myTable company="<<Fgets(lnHandle,4096)>>" address="<<Fgets(lnHandle,4096)>>"
	\\ CityState="<<Fgets(lnHandle,4096)>>"
  lcPhoneFax = Fgets(lnHandle,4096)
	\\ Phone="<<StrExtract(lcPhoneFax,'Phone:','Fax:')>>"
	\\ Fax="<<Substr(lcPhoneFax,Atc('Fax:',lcPhoneFax)+Len('Fax:'))>>">
  If !Feof(lnHandle)
    Fgets(lnHandle)
  Endif
Enddo
\</VFPData>
Set Textmerge To
Set Textmerge Off
Fclose(lnHandle)

You could rectify code and (add a table schema) then XmlToCursor().
Cetin