>Besides replacing the standard HELP in the TOOLS-OPTIONS-FILE LOCATIONS-HELP, is there any way to have that HELP AND the 1001.chm help files to both be options under the HELP Menu choice??
>
>Thanks
>
>Tommy

I have a foxstart program run when VFP starts up and in the program I do

DEFINE BAR 777 OF _MSM_SYSTM PROMPT "Hacker's Guide" AFTER _MST_HPSCH KEY ALT+F1
ON SELECTION BAR 777 OF _MSM_SYSTM DO HOME() + "foxhack.prg"

That puts the hackers guide underneith the help with a hot key of ALT+F1

then in foxhack.prg

LOCAL lc_oldclip, lc_selectd
*-- Save the old help
lc_help = SET('HELP', 2)
*-- Save the old cliptext
lc_oldclip = _cliptext

*-- Copy what I have selected into the clipboard
lc_selected = SPACE(0)
= SYS(1500, "_med_copy", "_medit")
lc_selected = _cliptext

*-- Reset the clipboard
_cliptext = lc_oldclip

IF FILE(HOME() + "HACKFOX.CHM")
   *-- Set help to hackers guide
   SET HELP TO (HOME() + "HACKFOX.CHM")
   HELP &lc_selected
   *-- Reset the help file
   SET HELP TO (lc_help)
ENDIF

Using this as an example I'm sure you can get the 1001.chm to work. Maybe there's an easry way but this works for me.