Be sure to requery. Here is an example doing the same thing using the current directory (look at the form's init):

*--Create a quick form with a listbox that displays all .xls files in
*--the current directory

oform=CREATEOBJECT('testform')
oform.show()
READ EVENTS
RETURN

DEFINE CLASS testform AS form


	DoCreate = .T.
	Caption = "Listbox Displaying all .xls files in current directory"
	Name = "Form1"
	DIMENSION myarray[1,5]


	ADD OBJECT list1 AS listbox WITH ;
		RowSourceType = 5, ;
		RowSource = "thisform.myarray", ;
		Height = 170, ;
		Left = 24, ;
		Top = 36, ;
		Width = 300, ;
		Name = "List1"


	PROCEDURE Init
		=adir(thisform.myarray,"*.xls")
		DODEFAULT()
		*--This is the key part to refresh the listbox
		thisform.list1.requery()
	ENDPROC

	PROCEDURE UNLOAD
		DODEFAULT()
		CLEAR EVENTS
	ENDPROC

ENDDEFINE

>Okay,
>
>For some reason this is getting to me and I can't figure it out. I have a array property on a form myarray[1,5]. I then want to do something like this
>=adir(thisform.myarray,"*.xls"). Works Fine.. however i have a list box bound to thisform.myarray and it will only display the first element.
>
>
>Thanks in advance,
>
>Paul