Bill-

>I'm using VFP 7.0
>

>myForm.myContainer1.myPageFrame.Page4.myContainer2.uiEnable()
>LPARAMETERS lEnable
>if lEnable
>  This.Refresh()
>endif
>

>When I run this form and change to Page4, none of the controls inside myContainer2 get refreshed(), but if I step through the code with the Trace Window, they do.

Bugs related to pages activating are frequently masked when using the trace window since the debugger windows will force pages to activate and deactivate. So, I'm not surprised that you see a difference. As for the issue, I tried to duplicate the problem with a simple example, in 7.0 SP 1, and was unable to do so. The following is my attempt, do you see the same problem with this code?

PUBLIC oform1

oform1=NEWOBJECT("myForm")
oform1.SHOW
RETURN

DEFINE CLASS myForm AS FORM

  CAPTION = "Form1"
  NAME = "Form1"

  ADD OBJECT pageframe1 AS myPageFrame

ENDDEFINE

DEFINE CLASS myPageFrame AS PAGEFRAME
  PAGECOUNT = 0
  TOP = 37
  LEFT = 30
  WIDTH = 312
  HEIGHT = 169
  NAME = "Pageframe1"

  ADD OBJECT Page1 AS myPage
  ADD OBJECT Page2 AS myPage

ENDDEFINE

DEFINE CLASS myPage AS PAGE
  ADD OBJECT container1 AS myContainer
ENDDEFINE

DEFINE CLASS myContainer AS CONTAINER

  TOP = 25
  LEFT = 21
  WIDTH = 265
  HEIGHT = 89
  NAME = "Container1"

  ADD OBJECT text1 AS TEXTBOX WITH ;
    HEIGHT = 23, ;
    LEFT = 82, ;
    TOP = 32, ;
    WIDTH = 100, ;
    NAME = "Text1"

  PROCEDURE UIENABLE
  LPARAMETERS lEnable
  IF lEnable
    THIS.REFRESH()
  ENDIF

  PROCEDURE text1.REFRESH
  THIS.VALUE = SECONDS()

ENDDEFINE