Oi José,

O exemplo abaixo, extraído do capítulo 13 do meu livro "Visual FoxPro 8 para Desenvolvedores", demonstra como você poderia usar a propriedade "CursorSchema" da classe CursorAdapter, que o Martín citou em outra mensagem.

A conexão está sendo feita para o database Northwind, que vem com o SQL Server 2000, mas alterando os dados de conexão, você poderá adaptá-lo aos seus bancos de dados.

Espero que ajude!

LOCAL loCurPedidos as CursorAdapter

CLOSE TABLES 
CLOSE DATABASES all

loCurPedidos = CREATEOBJECT("CAPedidos")

BROWSE FONT "Verdana", 14

loCurPedidos = null



*--
*-- CAPedidos
*--
DEFINE CLASS CAPedidos as CursorAdapter 

  HIDDEN StrConexao     && String de conexão ODBC
  
  StrConexao = "Driver={SQL Server}; " + ;
               "Server=(local); "      + ;
               "Database=Northwind; "  + ;
               "UID=sa; PWD=;"
  
  PROCEDURE Init
    WITH This
      .SendUpdates    = .T.
      .DataSourceType = "ODBC"
      .DataSource     = SQLSTRINGCONNECT(.StrConexao)
      .Alias          = "Pedidos"
      .SelectCmd      = "Select OrderID, CustomerID, OrderDate " + ;
                        "from Orders"
      .CursorSchema   = "OrderID I, CustomerID C(10), OrderDate D"
      .CursorFill(.T.)
    ENDWITH 
  ENDPROC 
  
 
ENDDEFINE 

Uma abraço!