>Hello all
>
>I have 12 tables say empJan,empFeb,empMar...empDec.how can i get the data for the range that user specifies. for eg if user selects JAN..MAY, i need to get data into one cursor. right now i use procedure code to do this, is it possible thru SQL/ Stored Procedures.
>
>TIA

Akhan,
Possible by SQL through unions. However thinking SQL subqueries have a limit of 10 and a year has 12 months you might need to divide it into more than one SQLs.
IMHO not playing with SQL and directly using xbase would be neater and (faster?). I think all structures are same.

GetRangeCursor('Jan','May','myCursor')
GetRangeCursor('Feb','May')
GetRangeCursor('Feb')

Function GetRangeCursor
Lparameters tcStart,tcEnd,tcCursorName
tcCursorName = Iif(Empty(m.tcCursorName),'empRange',m.tcCursorName)
If Empty(m.tcEnd)
  Select * ;
    from ( 'Emp'+m.tcStart ) ;
    into Cursor (m.tcCursorName) ;
    readwrite
  Return
Endif
Local Array aTables[12]
Local ix
For ix=1 To 12
  aTables[m.ix] = Upper('Emp'+Left(Cmonth(Date(2000,m.ix,1)),3))
Endfor
Select * ;
  from ( aTables[Ascan(aTables,'EMP'+Upper(m.tcStart))] ) ;
  into Cursor (m.tcCursorName) ;
  readwrite
For ix = Ascan(aTables,'EMP'+Upper(m.tcStart)) + 1 To ;
    Ascan(aTables,'EMP'+Upper(m.tcEnd))
  Append From ( aTables[m.ix] )
Endfor

Cetin