Is it a web application? If so, you might just want to use an SMTP server for e-mail. here's some code from ActiveVFP:

********************************************
*** Function: Send SMTP email using CDO(2000/XP) or CDONTS(NT). 
************************************************************************
FUNCTION email
LOCAL lcFileName, lcFileDesc, llCDO
llCDO=.T.
DO CASE
* Tests for Windows 2000
	CASE "5.00" $ OS()
		llCDO = .T.
	CASE "NT 4.00" $ OS()  && must use CDONTS
		llCDO = .F.
* Tests for Windows 95
	CASE "4.00" $ OS()
		llCDO = .F.
* Tests for Windows 98
	CASE "4.10" $ OS()
		llCDO = .F.
* Tests for Windows Me
	CASE "4.90" $ OS()
		llCDO = .F.
	OTHERWISE  && XP?
		llCDO = .T.
ENDCASE
IF llCDO
	#DEFINE cdoSendUsingPort 2
	#DEFINE smtpserverport 25
	#DEFINE smtpserver 'fireball.dotcomsolution.com' && replace with your SMTP server

	LOCAL loMsg
	loMsg = NEWOBJECT("CDO.Message")

	WITH loMsg
		IF !EMPTY(oRequest.FORM("txtMailFrom"))
	   		.FROM = oRequest.FORM("txtMailFrom")
	   	ENDIF
	   	IF !EMPTY(oRequest.FORM("txtMailTo"))
	   		.TO = oRequest.FORM("txtMailTo")
	   	ENDIF
	   	IF !EMPTY(oRequest.FORM("txtMailBcc"))
	   		.BCC = oRequest.FORM("txtMailBcc")
	   	ENDIF
	   	IF !EMPTY(oRequest.FORM("txtMailSubject"))
	   		.Subject = oRequest.FORM("txtMailSubject")
	   	ENDIF
	   	IF !EMPTY(oRequest.FORM("S1"))
	   		.TextBody = oRequest.FORM("S1")
	   	ENDIF
	   .Configuration.FIELDS("http://schemas.microsoft.com/cdo/configuration/sendusing").VALUE = cdoSendUsingPort
	   .Configuration.FIELDS("http://schemas.microsoft.com/cdo/configuration/smtpserver").VALUE = smtpserver
	   .Configuration.FIELDS("http://schemas.microsoft.com/cdo/configuration/smtpserverport").VALUE = smtpserverport
	   .Configuration.FIELDS.UPDATE
	   .SEND
	ENDWITH
	loMsg = NULL
ELSE  && use CDONTS,IIS SMTP(must be started)
	#DEFINE CdoBodyFormatHTML  0 && Body property is HTML
	#DEFINE CdoBodyFormatText  1 && Body property is plain text (default)
	#DEFINE CdoMailFormatMime  0 && NewMail object is in MIME format
	#DEFINE CdoMailFormatText  1 && NewMail object is plain text (default)
	#DEFINE CdoLow     0         && Low importance
	#DEFINE CdoNormal  1         && Normal importance (default)
	#DEFINE CdoHigh    2         && High importance
	#DEFINE CdoEncodingUUencode  0     && The attachment is to be in UUEncode format (default)  
	#DEFINE CdoEncodingBase64    1     && The attachment is to be in base 64 format  

	lcFileName=oRequest.FORM("txtMailAttachment")
	lcFileDesc=oRequest.FORM("txtMailFileDesc")
	oMail = CreateObject("CDONTS.Newmail")
	oMail.MailFormat = cdoMailFormatMIME
	IF !EMPTY(oRequest.FORM("txtMailFrom"))
		oMail.From = oRequest.FORM("txtMailFrom")
	ENDIF
	IF !EMPTY(oRequest.FORM("txtMailTo"))
		oMail.To = oRequest.FORM("txtMailTo")
	ENDIF
	IF !EMPTY(oRequest.FORM("txtMailBcc"))
		oMail.bcc = oRequest.FORM("txtMailBcc")
	ENDIF
	IF !EMPTY(oRequest.FORM("txtMailReplyTo"))
		oMail.Value("Reply-To") = oRequest.FORM("txtMailReplyTo")
	ENDIF
	IF !EMPTY(oRequest.FORM("D1"))
		oMail.Importance = VAL(oRequest.FORM("D1"))
	ENDIF
	IF !EMPTY(oRequest.FORM("txtMailSubject"))
		oMail.Subject = oRequest.FORM("txtMailSubject")
	ENDIF
	IF !EMPTY(oRequest.FORM("S1"))
		oMail.Body = oRequest.FORM("S1")
	ENDIF
	IF !EMPTY(lcFileName) .AND. FILE(lcFileName)
		oMail.AttachFile(lcFileName,lcFileDesc)
	ENDIF
	oMail.Send
ENDIF

>Hello,
>
>I am adding e-mail to our application and I need to find code or what ever that will allow me to send a message to what ever the default e-mail client is. The e-mail client will send the e-mail message and keep track of server, logins etc.
>
>Thanks for your help!!!!
>
>-Greg