I think I have already fixed this one. At the beginning of the CABuilder PRG file, and after all the Comments that appear betweem the TEXT TO lcReadMe/ENDTEXT, does your code look like the following:

LOCAL loForm, loBuilder, lcFolder1, lcFolder2, lcClassLib, lcExclude
loForm = NEWOBJECT('frmCABuilder', FORCEEXT(PROGRAM(), [prg]))
loForm.Show(1)
IF loForm.lCanceled
	loForm.Release()
	RETURN
ENDIF
lcFolder1 = ALLTRIM(loForm.txtVCXFolder.Value)
IF NOT DIRECTORY(lcFolder1)
	MD (lcFolder1)
ENDIF
lcFolder2 = ALLTRIM(loForm.txtSPFolder.Value)
IF NOT DIRECTORY(lcFolder2)
	MD (lcFolder2)
ENDIF
*!* 
*!* I think this next line of code fixed that bug
*!* 
lcClassLib = ADDBS(lcFolder1) + JUSTSTEM(JUSTFNAME(loForm.txtVCXName.Value))
lcExclude  = ALLTRIM(loForm.txtExclude.Value)
loBuilder  = NEWOBJECT('CABuilder', FORCEEXT(PROGRAM(), [prg]))
WITH loBuilder
	.cReadMeCode = lcReadMe
	.lSingleVCX  = (loForm.optLibOption.Value = 1)
	.cCAPrefix   = ALLTRIM(loForm.txtPrefix.Value)
	.cClassLib   = lcClassLib
	.cLibFolder  = lcFolder1

>Bug report
>
>FORCEEXT(lcLib, [VCX]) = F:\VFPAPPS\LOCK\CLASS\_CA_Taika1.VCX
>FULLPATH(THIS.cLibFolder)) = F:\VFPAPPS\LOCK\CLASS\
>THIS.lSingleVCX = .F. ==>>
>lcFullPath = ADDBS(FULLPATH(THIS.cLibFolder)) + FORCEEXT(lcLib, [VCX])
>*----------
>lcFullPath = F:\VFPAPPS\LOCK\CLASS\F:\VFPAPPS\LOCK\CLASS\_CA_Taika1.VCX
>...
>IF EMPTY(lcLib) OR FILE(lcFullPath) ==>> This is .F.
>==>>
>THIS.cClassLib = lcFullPath
>==>> Error
>
>
>

>	PROTECTED PROCEDURE GetClassLibName
>		LPARAMETERS tcName
>		IF VARTYPE(tcName) <> [C] OR THIS.lSingleVCX
>			tcName = []
>		ENDIF
>		tcName = ALLTRIM(tcName)
>		LOCAL lcLib, lcFullPath
>		lcLib = IIF(EMPTY(tcName), THIS.cClassLib, [CA_] + tcName)
>		IF THIS.lSingleVCX
>			lcFullPath = FORCEEXT(lcLib, [VCX])
>		ELSE
>			lcFullPath = ADDBS(FULLPATH(THIS.cLibFolder)) + FORCEEXT(lcLib, [VCX])
>		ENDIF
>		IF EMPTY(lcLib) OR FILE(lcFullPath)
>			lcLib = GETFILE([VCX], [ClassLib Name], [OK], 0, [Specify a NEW ClassLib Name for the CA Classes])
>			IF NOT EMPTY(lcLib)
>				lcLib = FORCEEXT(lcLib, [VCX])
>			ENDIF
>			IF EMPTY(lcLib) OR UPPER(lcLib) == [UNTITLED.VCX] OR FILE(lcLib)
>				THIS.SetError([You must provide a valid name for a ClassLib that does not already exist.])
>				RETURN .f.
>			ENDIF
>			lcFullPath = lcLib
>		ENDIF
>		THIS.cClassLib = lcFullPath
>	ENDPROC
>

>
>AT