>I am highlighting rows in my grids using the DynamicBackColor property and updating this value in the AfterRowColChange event. This works great, however I was wondering if there was a way to make the entire row look highlighted. Right now one cell within the row always "looks" selected.
Hi Paul,
You can try following class :

**************************************************
*-- Class:        highlighted (c:\temp\test.vcx)
*-- ParentClass:  grid
*-- BaseClass:    grid
*
DEFINE CLASS highlighted AS grid

	Height = 200
	Width = 320
	ccurrecbackcolor = (RGB(255,255,0))
	ccurrecforecolor = (RGB(0,0,255))
	lingrid = .T.
	ncurrec = .F.
	Name = "highlighted"

	PROCEDURE AfterRowColChange
		LPARAMETERS nColIndex
		this.nCurRec = recno(This.RecordSource)
		thisform.LockScreen = .F.
		IF !this.lInGrid
			this.refresh()
		ENDIF
	ENDPROC

	PROCEDURE BeforeRowColChange
		LPARAMETERS nColIndex
		thisform.LockScreen = this.lInGrid
	ENDPROC

	PROCEDURE Init
		WITH this
			IF !empty(.RecordSource)
				.nCurRec = recno(this.RecordSource)
				.SetAll("DynamicBackColor", "IIF(RecNo(This.RecordSource) = This.nCurRec," + ;
					str(this.cCurRecBackColor)+","+str(this.BackColor)+")", "Column")
				.SetAll("DynamicForeColor", "IIF(RecNo(This.RecordSource) = This.nCurRec," + ;
					str(this.cCurRecForeColor)+","+str(this.ForeColor)+")", "Column")
			ENDIF
		ENDWITH
	ENDPROC

	PROCEDURE Valid
		this.lInGrid = .F.
	ENDPROC

	PROCEDURE When
		this.lInGrid = .T.
	ENDPROC
ENDDEFINE
*
*-- EndDefine: highlighted
**************************************************

To follow rec pointer movement from outside of grid, set grid.nCurrec property and call grid.refresh.
Cetin