>Hi All,
>
>Is there a sample code that will calculate the number of years, months and days given a total number of days?
>
>Example. 365 days -> 1 year, 0 month and 0 day
>650 days -> 1 year, 9 months & ~11 days
>
>
>TIA

Mathew,
Day part depends on if there is a leap year or not.

oAge = Createobject("age")
oAge.CalcAge({^2004/02/28}, {^2004/02/28}+650)

? oAge.Years, oAge.Months, oAge.Days

oAge.CalcAge({^2001/02/28}, {^2001/02/28}+650)

? oAge.Years, oAge.Months, oAge.Days


Define Class age As Relation
  Years=0
  Months=0
  Days=0
  Procedure CalcAge
  Lparameters tdBirth, tdTarget
  Local ldTemp, ldBirth, lnDrop
  If tdBirth > tdTarget
    ldTemp = tdTarget
    tdTarget = tdBirth
    tdBirth = ldTemp
  Endif
  ldBirth = Date(Year(tdTarget),Month(tdBirth),Day(tdBirth))
  lnDrop = 0
  If Empty(ldBirth) && leap case
    ldBirth = Date(Year(tdTarget),3,1)
    lnDrop = Iif(Month(tdTarget)<=2,0,1)
  Endif
  With This
    .Years = Year(tdTarget) - Year(tdBirth) - (Iif(ldBirth > tdTarget,1,0))
    .Months = (Month(tdTarget) - Month(tdBirth) + 12 - ;
      (Iif(Day(tdBirth)>Day(tdTarget),1,0)))%12
    .Days = tdTarget - Gomonth(tdBirth,.Years*12+.Months) - lnDrop
  Endwith
Endproc
Enddefine

Cetin