>I need to create a builder to deal with multiple object, can this be done with BUILDERB. All I have seen in examples are single class, single operation type builders.
>
>TIA
>
>Rex
I didn't use Builderb for multipl objects. For multipl objects first create a builder (maybe you could play with builderb) and register it as MULTISELECT in builders.

* A form acting as a builder for multiselect objects
* Init
lparameters v1,v2,v3  
*** Not used here in fact, placeholder for builder.app expects 3 parms
* Apply button.click
nObjCount = aselobj(aTextBoxes)	&& Key function to reach objects at design time - check for optional parameter
for nObjNum = 1 to alen(aTextBoxes,1)
	if aTextBoxes[nObjNum].baseclass # "Textbox"
		loop
	endif	
	aTextBoxes[nObjNum].fontname = thisform.sampletext.fontname
	aTextBoxes[nObjNum].fontsize = thisform.sampletext.fontsize
	aTextBoxes[nObjNum].fontbold = thisform.sampletext.fontbold
	aTextBoxes[nObjNum].fontitalic = thisform.sampletext.fontitalic
	aTextBoxes[nObjNum].backcolor = thisform.sampletext.disabledbackcolor
	aTextBoxes[nObjNum].forecolor = thisform.sampletext.forecolor
	aTextBoxes[nObjNum].integralheight = thisform.sampletext.integralheight
	if !empty(thisform.cMethodName.value) and !empty(thisform.cMethod.value)
		aTextBoxes[nObjNum].writemethod(alltrim(thisform.cMethodName.value), alltrim(thisform.cMethod.value))
	endif
endfor
thisform.release

-Now this is saved as a class
-Use home()+"wizards\builder"
-Add an entry
-Replace name with something you want to be shown on builders list
* ie: Custom textbox builder
-Edit descript
-Type = MULTISELECT (operates on multipl objects)
-Edit classlib and class
You're ready to go. Select multipl objects then right click to select your "Custom textbox builder".
Cetin