>Hi Cetin,
>
>If I set titlebar=0 and I replace it with a label which has the color I want then I'll not be able to Click on the Title bar to move the form arround
>in run time.
>
>Any other suggestion.
>
>Thanks
>
>Bob

Local loForm

loForm = Createobject("oForm")
loForm.Show
Read Events

Define Class oForm As Form
    nHwnd = 0
    TitleBar = 0
    Width = 750
    Height = 400

    Add Object myTitle As Label ;
        with BackColor = Rgb(0,255,255), ;
        ForeColor = Rgb(255,0,0),;
        Caption = "I'm your form title", ;
        height = 25, Width = 750,;
        FontSize = 14, Alignment = 1
    Add Object myExit As CommandButton With ;
        Caption = 'x', FontName='Wingdings',;
        Height = 25, Width = 27, Left = 0

    Procedure Init()
    Declare ReleaseCapture In win32API
    Declare Integer SendMessage In win32API ;
        integer HWnd, Integer wMsg, ;
        integer wParam, Integer Lparam
Endproc

    Procedure myTitle.MouseMove
    Lparameters nButton, nShift, nXCoord, nYCoord
    ReleaseCapture()
    If nButton = 1
        SendMessage(Thisform.HWnd, 0x112, 0xF012, 0x0)
    Endif
Endproc

    Procedure myExit.Click
    Clear Events
    Thisform.Release
Endproc
Enddefine

Cetin